Initial commit

arm9/source/patches/platform/ace3ds/Ace3DSLoaderPlatform.h

@@ -0,0 +1,38 @@
+#pragma once
+#include "common.h"
+#include "../LoaderPlatform.h"
+#include "ace3dsReadSdAsm.h"
+#include "ace3dsReadSdDmaAsm.h"
+#include "ace3dsWriteSdAsm.h"
+
+/// @brief Implementation of LoaderPlatform for the Ace3DS+ flashcard
+class Ace3DSLoaderPlatform : public LoaderPlatform
+{
+public:
+    const SdReadPatchCode* CreateSdReadPatchCode(
+        PatchCodeCollection& patchCodeCollection, PatchHeap& patchHeap) const override
+    {
+        return patchCodeCollection.GetOrAddSharedPatchCode([&]
+        {
+            return new Ace3DSReadSdPatchCode(patchHeap);
+        });
+    }
+
+    const SdReadDmaPatchCode* CreateSdReadDmaPatchCode(PatchCodeCollection& patchCodeCollection,
+        PatchHeap& patchHeap, const void* miiCardDmaCopy32Ptr) const override
+    {
+        return patchCodeCollection.AddUniquePatchCode<Ace3DSReadSdDmaPatchCode>(
+            patchHeap, miiCardDmaCopy32Ptr);
+    }
+
+    const SdWritePatchCode* CreateSdWritePatchCode(
+        PatchCodeCollection& patchCodeCollection, PatchHeap& patchHeap) const override
+    {
+        return patchCodeCollection.GetOrAddSharedPatchCode([&]
+        {
+            return new Ace3DSWriteSdPatchCode(patchHeap);
+        });
+    }
+
+    bool HasDmaSdReads() const override { return true; }
+};

arm9/source/patches/platform/ace3ds/ace3dsReadSdAsm.h

@@ -0,0 +1,19 @@
+#pragma once
+#include "sections.h"
+#include "../SdReadPatchCode.h"
+
+DEFINE_SECTION_SYMBOLS(ace3ds_readsd);
+
+extern "C" void ace3ds_readSd(u32 srcSector, void* dst, u32 sectorCount);
+
+class Ace3DSReadSdPatchCode : public SdReadPatchCode
+{
+public:
+    explicit Ace3DSReadSdPatchCode(PatchHeap& patchHeap)
+        : SdReadPatchCode(SECTION_START(ace3ds_readsd), SECTION_SIZE(ace3ds_readsd), patchHeap) { }
+
+    const SdReadFunc GetSdReadFunction() const override
+    {
+        return (const SdReadFunc)GetAddressAtTarget((void*)ace3ds_readSd);
+    }
+};

arm9/source/patches/platform/ace3ds/ace3dsReadSdAsm.s

@@ -0,0 +1,83 @@
+.cpu arm7tdmi
+.section "ace3ds_readsd", "ax"
+.syntax unified
+.thumb
+
+// r0 = src sector
+// r1 = dst
+// r2 = sector count
+.global ace3ds_readSd
+.type ace3ds_readSd, %function
+ace3ds_readSd:
+    push {r4-r7,lr}
+
+    ldr r4, =0x040001A0
+    movs r3, #0x80
+    strb r3, [r4,#1]
+
+sector_loop:
+    // request sd read for sector 0xaabbccdd
+    // B9 aa bb cc dd 00 00 00
+    movs r3, #0xB9
+    strb r3, [r4,#0x8]
+    lsrs r3, r0, #24
+    strb r3, [r4,#0x9]
+    lsrs r3, r0, #16
+    strb r3, [r4,#0xA]
+    lsrs r3, r0, #8
+    strb r3, [r4,#0xB]
+    lsls r7, r0, #24
+    lsrs r7, r7, #24 // r7 = dd
+    str r7, [r4,#0xC] // storing as little-endian puts the bottom 8 bits as first byte
+
+    ldr r6, =0x04100010
+
+B9_poll_loop:
+    ldr r3, =0xA7586000
+    str r3, [r4,#4]
+
+B9_poll_transfer_loop:
+    ldrb r3, [r4,#6]
+    lsrs r3, r3, #8
+    bcc B9_poll_check_transfer_end
+    ldr r5, [r6]
+
+B9_poll_check_transfer_end:
+    ldrb r3, [r4,#7]
+    lsrs r3, r3, #8
+    bcs B9_poll_transfer_loop
+
+    cmp r5, #0
+    bne B9_poll_loop
+
+    movs r3, #0xBA
+    str r3, [r4,#0x8]
+    str r5, [r4,#0xC] // r5 is 0 here
+
+    ldr r3, =0xA1586000
+    str r3, [r4,#4]
+
+BA_data_loop:
+    ldrb r3, [r4,#6]
+    lsrs r3, r3, #8 // check if data is ready
+    bcc BA_data_loop_check_transfer_end // if not skip reading
+    
+    ldr r3, [r6]
+    stmia r1!, {r3}
+
+BA_data_loop_check_transfer_end:
+    ldrb r3, [r4,#7]
+    lsrs r3, r3, #8 // check if transfer is done
+    bcs BA_data_loop
+
+    adds r0, #1
+    subs r2, #1
+    bne sector_loop
+
+    pop {r4-r7,pc}
+
+.balign 4
+
+.pool
+
+.end

arm9/source/patches/platform/ace3ds/ace3dsReadSdDmaAsm.h

@@ -0,0 +1,30 @@
+#pragma once
+#include "sections.h"
+#include "../SdReadDmaPatchCode.h"
+
+DEFINE_SECTION_SYMBOLS(ace3ds_readsddma);
+
+extern "C" void ace3ds_readSdDma(u32 srcSector, u32 previousSrcSector, u32 dmaChannel, void* dst);
+extern "C" void ace3ds_finishReadSdDma(void);
+
+extern u32 ace3ds_readSdDma_miiCardDmaCopy32Ptr;
+
+class Ace3DSReadSdDmaPatchCode : public SdReadDmaPatchCode
+{
+public:
+    explicit Ace3DSReadSdDmaPatchCode(PatchHeap& patchHeap, const void* miiCardDmaCopy32Ptr)
+        : SdReadDmaPatchCode(SECTION_START(ace3ds_readsddma), SECTION_SIZE(ace3ds_readsddma), patchHeap)
+    {
+        ace3ds_readSdDma_miiCardDmaCopy32Ptr = (u32)miiCardDmaCopy32Ptr;
+    }
+
+    const SdReadDmaFunc GetSdReadDmaFunction() const override
+    {
+        return (const SdReadDmaFunc)GetAddressAtTarget((void*)ace3ds_readSdDma);
+    }
+
+    const SdReadDmaFinishFunc GetSdReadDmaFinishFunction() const override
+    {
+        return (const SdReadDmaFinishFunc)GetAddressAtTarget((void*)ace3ds_finishReadSdDma);
+    }
+};

arm9/source/patches/platform/ace3ds/ace3dsReadSdDmaAsm.s

@@ -0,0 +1,94 @@
+.cpu arm946e-s
+.section "ace3ds_readsddma", "ax"
+.syntax unified
+.thumb
+
+// r0 = src sector
+// r1 = previous src sector
+// r2 = dma channel
+// r3 = dst
+.global ace3ds_readSdDma
+.type ace3ds_readSdDma, %function
+ace3ds_readSdDma:
+    push {r4-r7,lr}
+
+    ldr r4, =0x040001A0
+    movs r7, #0x80
+    strb r7, [r4,#0x1]
+
+sector_loop:
+    // request sd read for sector 0xaabbccdd
+    // B9 aa bb cc dd 00 00 00
+    movs r7, #0xB9
+    strb r7, [r4,#0x8]
+    lsrs r7, r0, #24
+    strb r7, [r4,#0x9]
+    lsrs r7, r0, #16
+    strb r7, [r4,#0xA]
+    lsrs r7, r0, #8
+    strb r7, [r4,#0xB]
+    lsls r7, r0, #24
+    lsrs r7, r7, #24 // r7 = dd
+    str r7, [r4,#0xC] // storing as little-endian puts the bottom 8 bits as first byte
+
+    ldr r1, =0x04100010
+
+B9_poll_loop:
+    ldr r7, =0xA7586000
+    str r7, [r4,#0x4]
+
+B9_poll_transfer_loop:
+    ldrb r7, [r4,#0x6]
+    lsrs r7, r7, #8
+    bcc B9_poll_check_transfer_end
+    ldr r5, [r1]
+
+B9_poll_check_transfer_end:
+    ldrb r7, [r4,#0x7]
+    lsrs r7, r7, #8
+    bcs B9_poll_transfer_loop
+
+    cmp r5, #0
+    bne B9_poll_loop
+
+    // Setup data read card command
+    movs r7, #0xBA
+    str r7, [r4,#0x8]
+    str r5, [r4,#0xC] // r5 is 0 here
+
+readDataWithDma:
+    movs r0, r2 // DMA channel
+    movs r2, r3 // Destination
+    movs r3, #1
+    lsls r3, r3, #9 // (1 << 9) = 512 = count
+
+    ldr r6, ace3ds_readSdDma_miiCardDmaCopy32Ptr
+    blx r6
+
+BA_data_dma:
+    movs r7, #0xC0 // select rom mode, with irq
+    strb r7, [r4,#0x1]
+    ldr r7, =0xA1586000
+    str r7, [r4,#0x4]
+
+    pop {r4-r7,pc}
+
+.balign 4
+
+.global ace3ds_readSdDma_miiCardDmaCopy32Ptr
+ace3ds_readSdDma_miiCardDmaCopy32Ptr:
+    .word 0
+
+.pool
+
+.global ace3ds_finishReadSdDma
+.type ace3ds_finishReadSdDma, %function
+ace3ds_finishReadSdDma:
+    // No cleanup needed on this platform.
+    bx lr
+
+.balign 4
+
+.pool
+
+.end

arm9/source/patches/platform/ace3ds/ace3dsWriteSdAsm.h

@@ -0,0 +1,19 @@
+#pragma once
+#include "sections.h"
+#include "../SdWritePatchCode.h"
+
+DEFINE_SECTION_SYMBOLS(ace3ds_writesd);
+
+extern "C" void ace3ds_writeSd(u32 dstSector, const void* src, u32 sectorCount);
+
+class Ace3DSWriteSdPatchCode : public SdWritePatchCode
+{
+public:
+    explicit Ace3DSWriteSdPatchCode(PatchHeap& patchHeap)
+        : SdWritePatchCode(SECTION_START(ace3ds_writesd), SECTION_SIZE(ace3ds_writesd), patchHeap) { }
+
+    const SdWriteFunc GetSdWriteFunction() const override
+    {
+        return (const SdWriteFunc)GetAddressAtTarget((void*)ace3ds_writeSd);
+    }
+};

arm9/source/patches/platform/ace3ds/ace3dsWriteSdAsm.s

@@ -0,0 +1,88 @@
+.cpu arm7tdmi
+.section "ace3ds_writesd", "ax"
+.syntax unified
+.thumb
+
+// r0 = dst sector
+// r1 = src
+// r2 = sector count
+.global ace3ds_writeSd
+.type ace3ds_writeSd, %function
+ace3ds_writeSd:
+    push {r4-r7,lr}
+
+    ldr r4, =0x040001A0
+    movs r3, #0x80
+    strb r3, [r4,#1]
+
+sector_loop:
+    movs r5, #0xBC // for calculating command checksum
+    // write at sd sector 0xaabbccdd
+    // BB aa bb cc dd 00 00 00
+    movs r3, #0xBB
+    strb r3, [r4,#0x8]
+    lsrs r3, r0, #24
+    eors r5, r3
+    strb r3, [r4,#0x9]
+    lsrs r3, r0, #16
+    eors r5, r3
+    strb r3, [r4,#0xA]
+    lsrs r3, r0, #8
+    eors r5, r3
+    strb r3, [r4,#0xB]
+    lsls r7, r0, #24
+    lsrs r7, r7, #24 // r7 = dd
+    eors r5, r7
+    str r7, [r4,#0xC] // storing as little-endian puts the bottom 8 bits as first byte
+
+    ldr r6, =0x04100010
+
+    ldr r3, =0xE1586000
+    str r3, [r4,#4]
+
+BB_data_loop:
+    ldrb r3, [r4,#6]
+    lsrs r3, r3, #8 // check if ready to write
+    bcc BB_data_loop_check_transfer_end // if not skip reading
+    
+    ldmia r1!, {r3}
+    str r3, [r6]
+
+BB_data_loop_check_transfer_end:
+    ldrb r3, [r4,#7]
+    lsrs r3, r3, #8 // check if transfer is done
+    bcs BB_data_loop
+
+    movs r3, #0xBC
+    strb r3, [r4,#0x8]
+    strb r5, [r4,#0xF] // checksum
+
+BC_poll_loop:
+    ldr r3, =0xA7586000
+    str r3, [r4,#4]
+
+BC_poll_transfer_loop:
+    ldrb r3, [r4,#6]
+    lsrs r3, r3, #8
+    bcc BC_poll_check_transfer_end
+    ldr r5, [r6]
+
+BC_poll_check_transfer_end:
+    ldrb r3, [r4,#7]
+    lsrs r3, r3, #8
+    bcs BC_poll_transfer_loop
+
+    cmp r5, #0
+    bne BC_poll_loop
+
+    adds r0, #1
+    subs r2, #1
+    bne sector_loop
+
+    pop {r4-r7,pc}
+
+.balign 4
+
+.pool
+
+.end