Initial commit

arm9/source/patches/platform/g003/G003LoaderPlatform.h

@@ -0,0 +1,38 @@
+#pragma once
+#include "common.h"
+#include "../LoaderPlatform.h"
+#include "g003ReadSdAsm.h"
+#include "g003ReadSdDmaAsm.h"
+#include "g003WriteSdAsm.h"
+
+/// @brief Implementation of LoaderPlatform for the GMP-Z003 flashcard
+class G003LoaderPlatform : public LoaderPlatform
+{
+public:
+    const SdReadPatchCode* CreateSdReadPatchCode(
+        PatchCodeCollection& patchCodeCollection, PatchHeap& patchHeap) const override
+    {
+        return patchCodeCollection.GetOrAddSharedPatchCode([&]
+        {
+            return new G003ReadSdPatchCode(patchHeap);
+        });
+    }
+
+    const SdReadDmaPatchCode* CreateSdReadDmaPatchCode(PatchCodeCollection& patchCodeCollection,
+        PatchHeap& patchHeap, const void* miiCardDmaCopy32Ptr) const override
+    {
+        return patchCodeCollection.AddUniquePatchCode<G003ReadSdDmaPatchCode>(
+            patchHeap, miiCardDmaCopy32Ptr);
+    }
+
+    const SdWritePatchCode* CreateSdWritePatchCode(
+        PatchCodeCollection& patchCodeCollection, PatchHeap& patchHeap) const override
+    {
+        return patchCodeCollection.GetOrAddSharedPatchCode([&]
+        {
+            return new G003WriteSdPatchCode(patchHeap);
+        });
+    }
+
+    bool HasDmaSdReads() const override { return true; }
+};

arm9/source/patches/platform/g003/g003ReadSdAsm.h

@@ -0,0 +1,19 @@
+#pragma once
+#include "sections.h"
+#include "../SdReadPatchCode.h"
+
+DEFINE_SECTION_SYMBOLS(g003_readsd);
+
+extern "C" void g003_readSd(u32 srcSector, void* dst, u32 sectorCount);
+
+class G003ReadSdPatchCode : public SdReadPatchCode
+{
+public:
+    explicit G003ReadSdPatchCode(PatchHeap& patchHeap)
+        : SdReadPatchCode(SECTION_START(g003_readsd), SECTION_SIZE(g003_readsd), patchHeap) { }
+
+    const SdReadFunc GetSdReadFunction() const override
+    {
+        return (const SdReadFunc)GetAddressAtTarget((void*)g003_readSd);
+    }
+};

arm9/source/patches/platform/g003/g003ReadSdAsm.s

@@ -0,0 +1,88 @@
+.cpu arm7tdmi
+.section "g003_readsd", "ax"
+.syntax unified
+.thumb
+
+// r0 = src sector
+// r1 = dst
+// r2 = sector count
+.global g003_readSd
+.type g003_readSd, %function
+g003_readSd:
+    push {r4-r7,lr}
+
+    ldr r4, =0x040001A0
+    movs r3, #0x80
+    strb r3, [r4,#1]
+
+sector_loop:
+    // request sd read for sector, sector << 1 == 0xaabbccdd
+    // C9 bb cc dd 00 00 00 aa
+
+    // left shift sector address 1
+    lsls r7, r0, #1
+
+    // start copy to MCCMD1
+    movs r3, #0xC9
+    strb r3, [r4,#0x8]
+    lsrs r3, r7, #24
+    strb r3, [r4,#0xF] // place MSByte of sector address at end of command instead
+    lsrs r3, r7, #16
+    strb r3, [r4,#0x9]
+    lsrs r3, r7, #8
+    strb r3, [r4,#0xA]
+    // Ace3DS+ code uses str, but G003 doesn't store the last byte at u8 MCCMD1[4].
+    // So we use strb just like the other bytes.
+    strb r7, [r4,#0xB]
+
+    ldr r6, =0x04100010
+
+C9_poll_loop:
+    ldr r3, =0xA7586000
+    str r3, [r4,#4]
+
+C9_poll_transfer_loop:
+    ldrb r3, [r4,#6]
+    lsrs r3, r3, #8
+    bcc C9_poll_check_transfer_end
+    ldr r5, [r6]
+
+C9_poll_check_transfer_end:
+    ldrb r3, [r4,#7]
+    lsrs r3, r3, #8
+    bcs C9_poll_transfer_loop
+
+    cmp r5, #0
+    bne C9_poll_loop
+
+    movs r3, #0xCA
+    str r3, [r4,#0x8]
+    str r5, [r4,#0xC] // r5 is 0 here
+
+    ldr r3, =0xA1586000
+    str r3, [r4,#4]
+
+CA_data_loop:
+    ldrb r3, [r4,#6]
+    lsrs r3, r3, #8 // check if data is ready
+    bcc CA_data_loop_check_transfer_end // if not skip reading
+    
+    ldr r3, [r6]
+    stmia r1!, {r3}
+
+CA_data_loop_check_transfer_end:
+    ldrb r3, [r4,#7]
+    lsrs r3, r3, #8 // check if transfer is done
+    bcs CA_data_loop
+
+    adds r0, #1
+    subs r2, #1
+    bne sector_loop
+
+    pop {r4-r7,pc}
+
+.balign 4
+
+.pool
+
+.end

arm9/source/patches/platform/g003/g003ReadSdDmaAsm.h

@@ -0,0 +1,30 @@
+#pragma once
+#include "sections.h"
+#include "../SdReadDmaPatchCode.h"
+
+DEFINE_SECTION_SYMBOLS(g003_readsddma);
+
+extern "C" void g003_readSdDma(u32 srcSector, u32 previousSrcSector, u32 dmaChannel, void* dst);
+extern "C" void g003_finishReadSdDma(void);
+
+extern u32 g003_readSdDma_miiCardDmaCopy32Ptr;
+
+class G003ReadSdDmaPatchCode : public SdReadDmaPatchCode
+{
+public:
+    explicit G003ReadSdDmaPatchCode(PatchHeap& patchHeap, const void* miiCardDmaCopy32Ptr)
+        : SdReadDmaPatchCode(SECTION_START(g003_readsddma), SECTION_SIZE(g003_readsddma), patchHeap)
+    {
+        g003_readSdDma_miiCardDmaCopy32Ptr = (u32)miiCardDmaCopy32Ptr;
+    }
+
+    const SdReadDmaFunc GetSdReadDmaFunction() const override
+    {
+        return (const SdReadDmaFunc)GetAddressAtTarget((void*)g003_readSdDma);
+    }
+
+    const SdReadDmaFinishFunc GetSdReadDmaFinishFunction() const override
+    {
+        return (const SdReadDmaFinishFunc)GetAddressAtTarget((void*)g003_finishReadSdDma);
+    }
+};

arm9/source/patches/platform/g003/g003ReadSdDmaAsm.s

@@ -0,0 +1,100 @@
+.cpu arm946e-s
+.section "g003_readsddma", "ax"
+.syntax unified
+.thumb
+
+// r0 = src sector
+// r1 = previous src sector
+// r2 = dma channel
+// r3 = dst
+.global g003_readSdDma
+.type g003_readSdDma, %function
+g003_readSdDma:
+    push {r4-r7,lr}
+
+    ldr r4, =0x040001A0
+    movs r7, #0x80
+    strb r7, [r4,#0x1]
+
+sector_loop:
+    // request sd read for sector, sector << 1 == 0xaabbccdd
+    // C9 bb cc dd 00 00 00 aa
+
+    // left shift sector address 1
+    lsls r0, r0, #1
+
+    movs r7, #0xC9
+    strb r7, [r4,#0x8]
+    lsrs r7, r0, #24
+    strb r7, [r4,#0xF] // place MSByte of sector address at end of command instead
+    lsrs r7, r0, #16
+    strb r7, [r4,#0x9]
+    lsrs r7, r0, #8
+    strb r7, [r4,#0xA]
+    lsls r7, r0, #24
+    lsrs r7, r7, #24 // r7 = dd
+    // Ace3DS+ code uses str, but G003 doesn't store the last byte at u8 MCCMD1[4].
+    // So we use strb just like the other bytes.
+    strb r7, [r4,#0xB]
+
+    ldr r1, =0x04100010
+
+C9_poll_loop:
+    ldr r7, =0xA7586000
+    str r7, [r4,#0x4]
+
+C9_poll_transfer_loop:
+    ldrb r7, [r4,#0x6]
+    lsrs r7, r7, #8
+    bcc C9_poll_check_transfer_end
+    ldr r5, [r1]
+
+C9_poll_check_transfer_end:
+    ldrb r7, [r4,#0x7]
+    lsrs r7, r7, #8
+    bcs C9_poll_transfer_loop
+
+    cmp r5, #0
+    bne C9_poll_loop
+
+    // Setup data read card command
+    movs r7, #0xCA
+    str r7, [r4,#0x8]
+    str r5, [r4,#0xC] // r5 is 0 here
+
+readDataWithDma:
+    movs r0, r2 // DMA channel
+    movs r2, r3 // Destination
+    movs r3, #1
+    lsls r3, r3, #9 // (1 << 9) = 512 = count
+
+    ldr r6, g003_readSdDma_miiCardDmaCopy32Ptr
+    blx r6
+
+CA_data_dma:
+    movs r7, #0xC0 // select rom mode, with irq
+    strb r7, [r4,#0x1]
+    ldr r7, =0xA1586000
+    str r7, [r4,#0x4]
+
+    pop {r4-r7,pc}
+
+.balign 4
+
+.global g003_readSdDma_miiCardDmaCopy32Ptr
+g003_readSdDma_miiCardDmaCopy32Ptr:
+    .word 0
+
+.pool
+
+.global g003_finishReadSdDma
+.type g003_finishReadSdDma, %function
+g003_finishReadSdDma:
+    // No cleanup needed on this platform.
+    bx lr
+
+.balign 4
+
+.pool
+
+.end

arm9/source/patches/platform/g003/g003WriteSdAsm.h

@@ -0,0 +1,19 @@
+#pragma once
+#include "sections.h"
+#include "../SdWritePatchCode.h"
+
+DEFINE_SECTION_SYMBOLS(g003_writesd);
+
+extern "C" void g003_writeSd(u32 dstSector, const void* src, u32 sectorCount);
+
+class G003WriteSdPatchCode : public SdWritePatchCode
+{
+public:
+    explicit G003WriteSdPatchCode(PatchHeap& patchHeap)
+        : SdWritePatchCode(SECTION_START(g003_writesd), SECTION_SIZE(g003_writesd), patchHeap) { }
+
+    const SdWriteFunc GetSdWriteFunction() const override
+    {
+        return (const SdWriteFunc)GetAddressAtTarget((void*)g003_writeSd);
+    }
+};

arm9/source/patches/platform/g003/g003WriteSdAsm.s

@@ -0,0 +1,87 @@
+.cpu arm7tdmi
+.section "g003_writesd", "ax"
+.syntax unified
+.thumb
+
+// r0 = dst sector
+// r1 = src
+// r2 = sector count
+.global g003_writeSd
+.type g003_writeSd, %function
+g003_writeSd:
+    push {r4-r7,lr}
+
+    ldr r4, =0x040001A0
+    movs r3, #0x80
+    strb r3, [r4,#1]
+
+sector_loop:
+    // write at sd sector, sector << 1 == 0xaabbccdd
+    // C5 bb cc dd 00 00 00 aa
+
+    // left shift sector address 1
+    lsls r7, r0, #1
+
+    // start copy to MCCMD1
+    movs r3, #0xC5
+    strb r3, [r4,#0x8]
+    lsrs r3, r7, #24
+    strb r3, [r4,#0xF] // place MSByte of sector address at end of command instead
+    lsrs r3, r7, #16
+    strb r3, [r4,#0x9]
+    lsrs r3, r7, #8
+    strb r3, [r4,#0xA]
+    // Ace3DS+ code uses str, but G003 doesn't store the last byte at u8 MCCMD1[4].
+    // So we use strb just like the other bytes.
+    strb r7, [r4,#0xB]
+
+    ldr r6, =0x04100010
+
+    ldr r3, =0xE1586000
+    str r3, [r4,#4]
+
+C5_data_loop:
+    ldrb r3, [r4,#6]
+    lsrs r3, r3, #8 // check if ready to write
+    bcc C5_data_loop_check_transfer_end // if not skip reading
+    
+    ldmia r1!, {r3}
+    str r3, [r6]
+
+C5_data_loop_check_transfer_end:
+    ldrb r3, [r4,#7]
+    lsrs r3, r3, #8 // check if transfer is done
+    bcs C5_data_loop
+
+    movs r3, #0xC6
+    strb r3, [r4,#0x8]
+
+C6_poll_loop:
+    ldr r3, =0xA7586000
+    str r3, [r4,#4]
+
+C6_poll_transfer_loop:
+    ldrb r3, [r4,#6]
+    lsrs r3, r3, #8
+    bcc C6_poll_check_transfer_end
+    ldr r5, [r6]
+
+C6_poll_check_transfer_end:
+    ldrb r3, [r4,#7]
+    lsrs r3, r3, #8
+    bcs C6_poll_transfer_loop
+
+    cmp r5, #0
+    bne C6_poll_loop
+
+    adds r0, #1
+    subs r2, #1
+    bne sector_loop
+
+    pop {r4-r7,pc}
+
+.balign 4
+
+.pool
+
+.end