Initial commit

arm9/source/patches/platform/r4/R4LoaderPlatform.cpp

@@ -0,0 +1,40 @@
+#include "common.h"
+#include "R4LoaderPlatform.h"
+
+#define R4_CMD_CARD_INFO    0xB000000000000000ull
+#define R4_CMD_SEND_MAP     0xB400000000000000ull
+
+u32 R4LoaderPlatform::ReadCardInfo() const
+{
+    u32 response;
+    card_romSetCmd(R4_CMD_CARD_INFO);
+    card_romStartXfer(MCCNT1_RESET_OFF | MCCNT1_CMD_SCRAMBLE |
+        MCCNT1_CLOCK_SCRAMBLER | MCCNT1_READ_DATA_DESCRAMBLE |
+        MCCNT1_LATENCY2(24) | MCCNT1_LATENCY1(0) | MCCNT1_LEN_4, false);
+    card_romCpuRead(&response, 1);
+    return response;
+}
+
+void R4LoaderPlatform::PrepareClusterMap(bool isSave, u32 dirSector, u32 dirSectorOffset) const
+{
+    u32 fatEntryAddress = ((dirSector << 9) | dirSectorOffset) | (isSave ? 1 : 0);
+    card_romSetCmd(R4_CMD_SEND_MAP | ((u64)fatEntryAddress << 24));
+    u32 response;
+    do
+    {
+        card_romStartXfer(MCCNT1_RESET_OFF | MCCNT1_CMD_SCRAMBLE |
+            MCCNT1_CLOCK_SCRAMBLER | MCCNT1_READ_DATA_DESCRAMBLE |
+            MCCNT1_LATENCY2(24) | MCCNT1_LATENCY1(0) | MCCNT1_LEN_4, false);
+        card_romCpuRead(&response, 1);
+    } while (response);
+}
+
+void R4LoaderPlatform::PrepareRomBoot(u32 romDirSector, u32 romDirSectorOffset) const
+{
+    ReadCardInfo();
+    if (romDirSector != 0)
+    {
+        PrepareClusterMap(false, romDirSector, romDirSectorOffset);
+    }
+    ReadCardInfo();
+}

arm9/source/patches/platform/r4/R4LoaderPlatform.h

@@ -0,0 +1,47 @@
+#pragma once
+#include "common.h"
+#include <libtwl/card/card.h>
+#include "../LoaderPlatform.h"
+#include "r4ReadRomAsm.h"
+#include "r4ReadSdAsm.h"
+#include "r4WriteSdAsm.h"
+
+/// @brief Implementation of LoaderPlatform for the original R4 flashcard
+class R4LoaderPlatform : public LoaderPlatform
+{
+public:
+    const SdReadPatchCode* CreateSdReadPatchCode(
+        PatchCodeCollection& patchCodeCollection, PatchHeap& patchHeap) const override
+    {
+        return patchCodeCollection.GetOrAddSharedPatchCode([&]
+        {
+            return new R4ReadSdPatchCode(patchHeap);
+        });
+    }
+
+    const SdWritePatchCode* CreateSdWritePatchCode(
+        PatchCodeCollection& patchCodeCollection, PatchHeap& patchHeap) const override
+    {
+        return patchCodeCollection.GetOrAddSharedPatchCode([&]
+        {
+            return new R4WriteSdPatchCode(patchHeap);
+        });
+    }
+
+    const SdReadPatchCode* CreateRomReadPatchCode(
+        PatchCodeCollection& patchCodeCollection, PatchHeap& patchHeap) const override
+    {
+        return patchCodeCollection.GetOrAddSharedPatchCode([&]
+        {
+            return new R4ReadRomPatchCode(patchHeap);
+        });
+    }
+
+    bool HasRomReads() const override { return true; }
+
+    void PrepareRomBoot(u32 romDirSector, u32 romDirSectorOffset) const override;
+
+private:
+    u32 ReadCardInfo() const;
+    void PrepareClusterMap(bool isSave, u32 dirSector, u32 dirSectorOffset) const;
+};

arm9/source/patches/platform/r4/r4ReadRomAsm.h

@@ -0,0 +1,20 @@
+#pragma once
+#include "sections.h"
+#include "../SdReadPatchCode.h"
+
+DEFINE_SECTION_SYMBOLS(r4_readrom);
+
+extern "C" void r4_readRom(u32 srcSector, void* dst);
+
+class R4ReadRomPatchCode : public SdReadPatchCode
+{
+public:
+    explicit R4ReadRomPatchCode(PatchHeap& patchHeap)
+        : SdReadPatchCode(SECTION_START(r4_readrom), SECTION_SIZE(r4_readrom), patchHeap)
+    { }
+
+    const SdReadFunc GetSdReadFunction() const override
+    {
+        return (const SdReadFunc)GetAddressAtTarget((void*)r4_readRom);
+    }
+};

arm9/source/patches/platform/r4/r4ReadRomAsm.s

@@ -0,0 +1,76 @@
+.cpu arm7tdmi
+.section "r4_readrom", "ax"
+.syntax unified
+.thumb
+
+// r0 = src sector
+// r1 = dst
+.global r4_readRom
+.type r4_readRom, %function
+r4_readRom:
+    push {r4-r7,lr}
+    lsls r0, r0, #9 // rom sector to rom byte address
+    ldr r4, =0x040001A0
+    movs r3, #0x80
+    strb r3, [r4,#1]
+
+    // request rom read at rom address 0xaabbccdd
+    // B6 aa bb cc dd 00 00 00
+    movs r3, #0xB6
+    strb r3, [r4,#0x8]
+    lsrs r3, r0, #24
+    strb r3, [r4,#0x9]
+    lsrs r3, r0, #16
+    strb r3, [r4,#0xA]
+    lsrs r3, r0, #8
+    strb r3, [r4,#0xB]
+    lsls r0, r0, #24
+    lsrs r7, r0, #24 // r7 = dd
+    str r7, [r4,#0xC] // storing as little-endian puts the bottom 8 bits as first byte
+
+    ldr r6, =0x04100010
+
+B6_poll_loop:
+    ldr r3, =0xA7586000
+    str r3, [r4,#4]
+
+B6_poll_transfer_loop:
+    ldrb r3, [r4,#6]
+    lsrs r3, r3, #8
+    bcc B6_poll_check_transfer_end
+    ldr r2, [r6]
+
+B6_poll_check_transfer_end:
+    ldrb r3, [r4,#7]
+    lsrs r3, r3, #8
+    bcs B6_poll_transfer_loop
+
+    cmp r2, #0
+    bne B6_poll_loop
+
+    movs r3, #0xB7
+    strb r3, [r4,#0x8]
+
+    ldr r3, =0xA1586000
+    str r3, [r4,#4]
+
+B7_data_loop:
+    ldrb r3, [r4,#6]
+    lsrs r3, r3, #8 // check if data is ready
+    bcc B7_data_loop_check_transfer_end // if not skip reading
+    
+    ldr r3, [r6]
+    stmia r1!, {r3}
+
+B7_data_loop_check_transfer_end:
+    ldrb r3, [r4,#7]
+    lsrs r3, r3, #8 // check if transfer is done
+    bcs B7_data_loop
+
+    pop {r4-r7,pc}
+
+.balign 4
+
+.pool
+
+.end

arm9/source/patches/platform/r4/r4ReadSdAsm.h

@@ -0,0 +1,19 @@
+#pragma once
+#include "sections.h"
+#include "../SdReadPatchCode.h"
+
+DEFINE_SECTION_SYMBOLS(r4_readsd);
+
+extern "C" void r4_readSd(u32 srcSector, void* dst, u32 sectorCount);
+
+class R4ReadSdPatchCode : public SdReadPatchCode
+{
+public:
+    explicit R4ReadSdPatchCode(PatchHeap& patchHeap)
+        : SdReadPatchCode(SECTION_START(r4_readsd), SECTION_SIZE(r4_readsd), patchHeap) { }
+
+    const SdReadFunc GetSdReadFunction() const override
+    {
+        return (const SdReadFunc)GetAddressAtTarget((void*)r4_readSd);
+    }
+};

arm9/source/patches/platform/r4/r4ReadSdAsm.s

@@ -0,0 +1,83 @@
+.cpu arm7tdmi
+.section "r4_readsd", "ax"
+.syntax unified
+.thumb
+
+// r0 = src sector
+// r1 = dst
+// r2 = sector count
+.global r4_readSd
+.type r4_readSd, %function
+r4_readSd:
+    push {r4-r7,lr}
+    ldr r4, =0x040001A0
+    movs r3, #0x80
+    strb r3, [r4,#1]
+
+sector_loop:
+    // request sd read at byte address 0xaabbccdd
+    // B9 aa bb cc dd 00 00 00
+    lsls r7, r0, #9 // sd sector to sd byte address
+    movs r3, #0xB9
+    strb r3, [r4,#0x8]
+    lsrs r3, r7, #24
+    strb r3, [r4,#0x9]
+    lsrs r3, r7, #16
+    strb r3, [r4,#0xA]
+    lsrs r3, r7, #8
+    strb r3, [r4,#0xB]
+    lsls r3, r7, #24
+    lsrs r3, r3, #24 // r7 = dd
+    str r3, [r4,#0xC] // storing as little-endian puts the bottom 8 bits as first byte
+
+    ldr r6, =0x04100010
+
+B9_poll_loop:
+    ldr r3, =0xA7586000
+    str r3, [r4,#4]
+
+B9_poll_transfer_loop:
+    ldrb r3, [r4,#6]
+    lsrs r3, r3, #8
+    bcc B9_poll_check_transfer_end
+    ldr r5, [r6]
+
+B9_poll_check_transfer_end:
+    ldrb r3, [r4,#7]
+    lsrs r3, r3, #8
+    bcs B9_poll_transfer_loop
+
+    cmp r5, #0
+    bne B9_poll_loop
+
+    movs r3, #0xBA
+    str r3, [r4,#0x8]
+    str r5, [r4,#0xC] // r5 is 0 here
+
+    ldr r3, =0xA1586000
+    str r3, [r4,#4]
+
+BA_data_loop:
+    ldrb r3, [r4,#6]
+    lsrs r3, r3, #8 // check if data is ready
+    bcc BA_data_loop_check_transfer_end // if not skip reading
+
+    ldr r3, [r6]
+    stmia r1!, {r3}
+
+BA_data_loop_check_transfer_end:
+    ldrb r3, [r4,#7]
+    lsrs r3, r3, #8 // check if transfer is done
+    bcs BA_data_loop
+
+    adds r0, #1
+    subs r2, #1
+    bne sector_loop
+
+    pop {r4-r7,pc}
+
+.balign 4
+
+.pool
+
+.end

arm9/source/patches/platform/r4/r4WriteSdAsm.h

@@ -0,0 +1,19 @@
+#pragma once
+#include "sections.h"
+#include "../SdWritePatchCode.h"
+
+DEFINE_SECTION_SYMBOLS(r4_writesd);
+
+extern "C" void r4_writeSd(u32 dstSector, const void* src, u32 sectorCount);
+
+class R4WriteSdPatchCode : public SdWritePatchCode
+{
+public:
+    explicit R4WriteSdPatchCode(PatchHeap& patchHeap)
+        : SdWritePatchCode(SECTION_START(r4_writesd), SECTION_SIZE(r4_writesd), patchHeap) { }
+
+    const SdWriteFunc GetSdWriteFunction() const override
+    {
+        return (const SdWriteFunc)GetAddressAtTarget((void*)r4_writeSd);
+    }
+};

arm9/source/patches/platform/r4/r4WriteSdAsm.s

@@ -0,0 +1,83 @@
+.cpu arm7tdmi
+.section "r4_writesd", "ax"
+.syntax unified
+.thumb
+
+// r0 = dst sector
+// r1 = src
+// r2 = sector count
+.global r4_writeSd
+.type r4_writeSd, %function
+r4_writeSd:
+    push {r4-r7,lr}
+
+    ldr r4, =0x040001A0
+    movs r3, #0x80
+    strb r3, [r4,#1]
+
+sector_loop:
+    // write at sd byte address 0xaabbccdd
+    // BB aa bb cc dd 00 00 00
+    lsls r7, r0, #9 // sd sector to sd byte address
+    movs r3, #0xBB
+    strb r3, [r4,#0x8]
+    lsrs r3, r7, #24
+    strb r3, [r4,#0x9]
+    lsrs r3, r7, #16
+    strb r3, [r4,#0xA]
+    lsrs r3, r7, #8
+    strb r3, [r4,#0xB]
+    lsls r3, r7, #24
+    lsrs r3, r3, #24 // r7 = dd
+    str r3, [r4,#0xC] // storing as little-endian puts the bottom 8 bits as first byte
+
+    ldr r6, =0x04100010
+
+    ldr r3, =0xE1586000
+    str r3, [r4,#4]
+
+BB_data_loop:
+    ldrb r3, [r4,#6]
+    lsrs r3, r3, #8 // check if ready to write
+    bcc BB_data_loop_check_transfer_end // if not skip reading
+
+    ldmia r1!, {r3}
+    str r3, [r6]
+
+BB_data_loop_check_transfer_end:
+    ldrb r3, [r4,#7]
+    lsrs r3, r3, #8 // check if transfer is done
+    bcs BB_data_loop
+
+    movs r3, #0xBC
+    strb r3, [r4,#0x8]
+
+BC_poll_loop:
+    ldr r3, =0xA7586000
+    str r3, [r4,#4]
+
+BC_poll_transfer_loop:
+    ldrb r3, [r4,#6]
+    lsrs r3, r3, #8
+    bcc BC_poll_check_transfer_end
+    ldr r5, [r6]
+
+BC_poll_check_transfer_end:
+    ldrb r3, [r4,#7]
+    lsrs r3, r3, #8
+    bcs BC_poll_transfer_loop
+
+    cmp r5, #0
+    bne BC_poll_loop
+
+    adds r0, #1
+    subs r2, #1
+    bne sector_loop
+
+    pop {r4-r7,pc}
+
+.balign 4
+
+.pool
+
+.end