mirror of
https://github.com/thead-yocto-mirror/meta-external-toolchain
synced 2026-09-09 17:34:50 +02:00
3021923aff
Since external recipes don't require virtual/libc and the compilerlibs, we won't always get our rdeps on those from the shlibs processing, unless we depend on the packagedata from those recipes. Adding them to DEPENDS would have worked too, but would have been a lie in a sense, as we don't actually require those to "build", just package. Signed-off-by: Christopher Larson <kergoth@gmail.com>
37 lines
1.0 KiB
BlitzBasic
37 lines
1.0 KiB
BlitzBasic
SUMMARY = "gdb - GNU debugger"
|
|
HOMEPAGE = "http://www.gnu.org/software/gdb/"
|
|
SECTION = "devel"
|
|
PV := "${@external_run(d, 'gdb', '-v').splitlines()[0].split()[-1]}"
|
|
|
|
inherit external-toolchain
|
|
|
|
def get_gdb_license(d):
|
|
output = external_run(d, 'gdb', '-v')
|
|
if output != 'UNKNOWN':
|
|
for line in output.splitlines():
|
|
if line.startswith('License '):
|
|
lic = line.split(':', 1)[0]
|
|
return lic.replace('License ', '')
|
|
else:
|
|
return output
|
|
|
|
LICENSE := "${@get_gdb_license(d)}"
|
|
LICENSE[vardepvalue] = "${LICENSE}"
|
|
|
|
FILES_${PN} = "\
|
|
${bindir}/gdbserver \
|
|
${datadir}/gdb/guile \
|
|
${datadir}/gdb/python/gdb \
|
|
${datadir}/gdb/syscalls \
|
|
${datadir}/gdb/system-gdbinit \
|
|
${libdir}/libinproctrace.so \
|
|
"
|
|
INSANE_SKIP_${PN} += "dev-so"
|
|
FILES_${PN}-doc = "${mandir}/man1/gdbserver.1"
|
|
|
|
# Ensure that our rdeps are able to be set by shlibs processing
|
|
do_package[depends] += "\
|
|
virtual/libc:do_packagedata \
|
|
virtual/${TARGET_PREFIX}compilerlibs:do_packagedata \
|
|
"
|