mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-09-16 20:21:58 +02:00
f2c30f11c3
>From [1]: 3.34.2 ====== * Fix immediate screen blank after releasing inhibitor [Tim; #573] * Respond to frame callbacks regardless of damage [Jonas Ã….; !839] * Translate well-known selection atoms to mimetypes [Carlos; !842] * Fix Night Light on wayland [Jonas Ã….; !840] * Fix various copy+paste/DND regressions [Carlos; !848, #789, #842, #793, #845, #854] * Don't emit focus event after desctruction [Marco; gnome-shell#1704, !860] * Fix hang when opening not-responding dialog on Xorg [Carlos; !876] * Fix frozen grabs on Xorg after weeks of inactivity [Jonas Ã….; !886] * Fix triggering popups from stylus devices on wayland [Carlos; #886] * Support shadow framebuffers for offscreen rendering [Olivier; !917] * Fix hang after interacting with desktop icons on X11 [Marco; !909] * Don't double scale when getting absolute surface coordinates [Xiang; !915] * Kill window effects on destroy [Robert; !924] * Use partial damage for dma-buf and EGLImage buffers on wayland [Robert; #947] * Do not stack transients underneath their always-on-top parent [Florian; #587] * Fix KMS freeze after pageflip [Pekka; !953] * Fixed crashes [Robert, Jonas Ã…., Marco, Hans, Carlos, Tim; !856, !912, !895, !928, #591, !823, !960] * Plugged memory leaks [Niels, Robert, Carlos; !847, !868, !873] * Misc. bug fixes and cleanups [Daniel, Marco, Jonas Ã…., Georges, Cosimo, Florian, Hans, Robert, Jonas D.; !841, !764, !837, !846, !673, !811, !893, !925, !927, !940, !832] Contributors: Marco Trevisan (Treviño), Cosimo Cecchi, Tim Crawford, Jonas Dreßler, Xiang Fan, Olivier Fourdan, Carlos Garnacho, Hans de Goede, Niels De Graef, Tim Klocke, Robert Mader, Florian Müllner, Georges Basile Stavracas Neto, Pekka Paalanen, Daniel van Vugt, Jonas Ã…dahl Translators: Bruce Cowan [en_GB] [1] http://ftp.gnome.org/pub/gnome/sources/mutter/3.34/mutter-3.34.2.news Signed-off-by: Andreas Müller <schnitzeltony@gmail.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
97 lines
3.3 KiB
BlitzBasic
97 lines
3.3 KiB
BlitzBasic
SUMMARY = "Window and compositing manager based on Clutter"
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
|
|
DEPENDS = " \
|
|
xserver-xorg-cvt-native \
|
|
virtual/libx11 \
|
|
gtk+3 \
|
|
gdk-pixbuf \
|
|
cairo \
|
|
pango \
|
|
gsettings-desktop-schemas \
|
|
json-glib \
|
|
gnome-desktop3 \
|
|
gnome-settings-daemon \
|
|
libxtst \
|
|
libxkbfile \
|
|
xinerama \
|
|
"
|
|
|
|
GNOMEBASEBUILDCLASS = "meson"
|
|
|
|
inherit gnomebase gsettings gobject-introspection gettext upstream-version-is-even features_check
|
|
|
|
SRC_URI[archive.md5sum] = "4515ccdb762a243d65757f5ab073d206"
|
|
SRC_URI[archive.sha256sum] = "2d6f7763193766d4652d43d0d0de2e49e60ca571eca0a7f1e6341fbd67f90b2d"
|
|
SRC_URI += "file://0001-cogl-Fix-GLES2-fallback.patch"
|
|
|
|
# x11 is still manadatory - see meson.build
|
|
REQUIRED_DISTRO_FEATURES = "x11"
|
|
|
|
# systemd can be replaced by libelogind (not available atow - make systemd
|
|
# mandatory distro feature)
|
|
LOGIND ?= "systemd"
|
|
REQUIRED_DISTRO_FEATURES += "systemd"
|
|
|
|
# profiler requires sysprof 3.34 which is not willing to build atow
|
|
PACKAGECONFIG ??= " \
|
|
native-backend \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'opengl x11', 'opengl glx', '', d)} \
|
|
sm \
|
|
startup-notification \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'opengl wayland', 'wayland', '', d)} \
|
|
"
|
|
|
|
EXTRA_OEMESON += " \
|
|
-Dxwayland_path=${bindir}/Xwayland \
|
|
"
|
|
|
|
# combi-config - see meson_options.txt for more details
|
|
PACKAGECONFIG[native-backend] = "-Dnative_backend=true -Dudev=true, -Dnative_backend=false -Dudev=false, libdrm virtual/libgbm libinput ${LOGIND} virtual/egl virtual/libgles2 udev"
|
|
PACKAGECONFIG[opengl] = "-Dopengl=true, -Dopengl=true, virtual/libgl"
|
|
PACKAGECONFIG[glx] = "-Dglx=true, -Dglx=false"
|
|
PACKAGECONFIG[libwacom] = "-Dlibwacom=true, -Dlibwacom=false, libwacom"
|
|
PACKAGECONFIG[remote-desktop] = "-Dremote_desktop=true, -Dremote_desktop=false, pipewire"
|
|
PACKAGECONFIG[sm] = "-Dsm=true, -Dsm=false, libsm"
|
|
PACKAGECONFIG[profiler] = "-Dprofiler=true,-Dprofiler=false,sysprof"
|
|
PACKAGECONFIG[startup-notification] = "-Dstartup_notification=true, -Dstartup_notification=false, startup-notification, startup-notification"
|
|
PACKAGECONFIG[wayland] = "-Dwayland=true,-Dwayland=false,wayland wayland-native, xserver-xorg-xwayland"
|
|
PACKAGECONFIG[wayland-eglstream] = "-Dwayland_eglstream=true,-Dwayland_eglstream=false"
|
|
|
|
# yes they changed from mutter-4 -> mutter-5 recently so be perpared
|
|
MUTTER_API_NAME = "mutter-5"
|
|
|
|
do_install_append() {
|
|
# Add gir links in standard paths. That makes dependents life much easier
|
|
# to find them
|
|
install -d ${D}${datadir}/gir-1.0
|
|
for gir_full in `find ${D}${libdir}/${MUTTER_API_NAME} -name '*.gir'`; do
|
|
gir=`basename "$gir_full"`
|
|
ln -sr "${D}${libdir}/${MUTTER_API_NAME}/$gir" "${D}${datadir}/gir-1.0/$gir"
|
|
done
|
|
}
|
|
|
|
PACKAGES =+ "${PN}-tests"
|
|
|
|
FILES_${PN} += " \
|
|
${datadir}/gnome-control-center \
|
|
${libdir}/${MUTTER_API_NAME}/lib*${SOLIBS} \
|
|
${libdir}/${MUTTER_API_NAME}/*.typelib \
|
|
${libdir}/${MUTTER_API_NAME}/plugins \
|
|
"
|
|
|
|
FILES_${PN}-tests += " \
|
|
${datadir}/installed-tests \
|
|
${datadir}/${MUTTER_API_NAME}/tests \
|
|
${libexecdir}/installed-tests/${MUTTER_API_NAME} \
|
|
"
|
|
|
|
FILES_${PN}-dev += " \
|
|
${libdir}/${MUTTER_API_NAME}/*.gir \
|
|
${libdir}/${MUTTER_API_NAME}/lib*.so \
|
|
"
|
|
|
|
RDEPENDS_${PN} += "zenity"
|
|
|