mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-09-16 12:12:16 +02:00
cdb428e7c4
* based on discussion in pndeprecated thread: https://patchwork.openembedded.org/patch/137573/ update the messages to warn possible users that the recipe will be removed before the end of the next development cycle (before Yocto 2.4 is released). * updated with: sed -i 's/^\(PNBLACKLIST.*".*\)"/\1 - the recipe will be removed on 2017-09-01 unless the issue is fixed"/g' `git grep PNBLACKLIST | sed 's/:.*//g' | sort -u | xargs` * then noticed couple recipes being blacklisted only based on DISTRO_FEATURES, so removed those: meta-networking/recipes-support/lksctp-tools/lksctp-tools_1.0.17.bb meta-oe/recipes-connectivity/bluez/bluez-hcidump_2.5.bb meta-oe/recipes-connectivity/bluez/bluez4_4.101.bb meta-oe/recipes-connectivity/bluez/gst-plugin-bluetooth_4.101.bb meta-oe/recipes-navigation/foxtrotgps/foxtrotgps_1.1.1.bb meta-oe/recipes-navigation/gypsy/gypsy.inc meta-oe/recipes-navigation/navit/navit.inc meta-oe/recipes-support/opensync/libsyncml_0.5.4.bb * if it isn't fixed by this date, it's fair game to be removed whenever someone gets around to i Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
73 lines
2.4 KiB
BlitzBasic
73 lines
2.4 KiB
BlitzBasic
SUMMARY = "VirtualBox Linux Guest Drivers"
|
|
SECTION = "core"
|
|
LICENSE = "GPL-2.0"
|
|
LIC_FILES_CHKSUM = "file://${WORKDIR}/${VBOX_NAME}/COPYING;md5=e197d5641bb35b29d46ca8c4bf7f2660"
|
|
|
|
DEPENDS = "virtual/kernel"
|
|
|
|
inherit module kernel-module-split
|
|
|
|
COMPATIBLE_MACHINE = "(qemux86|qemux86-64)"
|
|
|
|
VBOX_NAME = "VirtualBox-${PV}"
|
|
|
|
SRC_URI = "http://download.virtualbox.org/virtualbox/${PV}/${VBOX_NAME}.tar.bz2 \
|
|
file://Makefile.utils \
|
|
"
|
|
SRC_URI[md5sum] = "8635387dec6cbfd576ba453355d4dc0c"
|
|
SRC_URI[sha256sum] = "af0776df6d03b2709cb76a69f055487bf12bdb3b4163e2a82959860300283046"
|
|
|
|
S = "${WORKDIR}/vbox_module"
|
|
|
|
export BUILD_TARGET_ARCH="${ARCH}"
|
|
export BUILD_TARGET_ARCH_x86-64="amd64"
|
|
export KERN_DIR="${STAGING_KERNEL_DIR}"
|
|
|
|
addtask export_sources before do_patch after do_unpack
|
|
|
|
do_export_sources() {
|
|
mkdir -p "${S}"
|
|
${WORKDIR}/${VBOX_NAME}/src/VBox/Additions/linux/export_modules ${T}/vbox_modules.tar.gz
|
|
tar -C "${S}" -xzf ${T}/vbox_modules.tar.gz
|
|
|
|
# add a mount utility to use shared folder from VBox Addition Source Code
|
|
mkdir -p "${S}/utils"
|
|
install ${WORKDIR}/${VBOX_NAME}/src/VBox/Additions/linux/sharedfolders/mount.vboxsf.c ${S}/utils
|
|
install ${WORKDIR}/${VBOX_NAME}/src/VBox/Additions/linux/sharedfolders/vbsfmount.c ${S}/utils
|
|
install ${S}/../Makefile.utils ${S}/utils/Makefile
|
|
|
|
}
|
|
|
|
# compile and install mount utility
|
|
do_compile_append() {
|
|
oe_runmake 'LD=${CC}' 'LDFLAGS=${LDFLAGS}' -C ${S}/utils
|
|
if ! [ -e vboxguest.ko -a -e vboxsf.ko -a -e vboxvideo.ko ] ; then
|
|
echo "ERROR: One of vbox*.ko modules wasn't built"
|
|
exit 1
|
|
fi
|
|
}
|
|
|
|
module_do_install() {
|
|
MODULE_DIR=${D}${nonarch_base_libdir}/modules/${KERNEL_VERSION}/kernel/misc
|
|
install -d $MODULE_DIR
|
|
install -m 644 vboxguest.ko $MODULE_DIR
|
|
install -m 644 vboxsf.ko $MODULE_DIR
|
|
install -m 644 vboxvideo.ko $MODULE_DIR
|
|
}
|
|
|
|
do_install_append() {
|
|
install -d ${D}${base_sbindir}
|
|
install -m 755 ${S}/utils/mount.vboxsf ${D}${base_sbindir}
|
|
}
|
|
|
|
PACKAGES += "kernel-module-vboxguest kernel-module-vboxsf kernel-module-vboxvideo"
|
|
RRECOMMENDS_${PN} += "kernel-module-vboxguest kernel-module-vboxsf kernel-module-vboxvideo"
|
|
|
|
FILES_${PN} = "${base_sbindir}"
|
|
|
|
# autoload if installed
|
|
KERNEL_MODULE_AUTOLOAD += "vboxguest vboxsf vboxvideo"
|
|
|
|
# http://errors.yoctoproject.org/Errors/Details/83333/
|
|
PNBLACKLIST[vboxguestdrivers] ?= "BROKEN: not compatible with default kernel version 4.8 - the recipe will be removed on 2017-09-01 unless the issue is fixed"
|