mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-09-16 12:12:16 +02:00
5a974137fa
Liense-Update : year updated to 2022. Changelog: ========= GitHub Actions: update script to same version as master update copyright year to 2022 keyingmaterialexporter.c: include strings.h remove unused sitnl.h file sample-plugin: New plugin for testing multiple auth plugins plug-ins: Disallow multiple deferred authentication plug-ins doc/Makefile: rebuild rst docs if input files change doc/options: clean up documentation for --proto and related options fix Changes.rst errors in 2.5.3 and 2.5.5 announcement Repair --inactive with 'bytes' argument larger 2Gbytes. Fix --mtu-disc maybe|yes on Linux. Preparing release 2.5.6 CI: github actions: keep "pdb" in artifacts auth_token.c: add NULL initialization vcpkg-ports/pkcs11-helper: bump to release 1.28 vcpkg-ports/pkcs11-helper: indicate OpenSSL EC support msvc: cleanup vcpkg: link lzo statically vcpkg-ports/pkcs11-helper: adapt to new upstream URL vcpkg-ports: add openssl 1.1.1n Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
76 lines
3.3 KiB
BlitzBasic
76 lines
3.3 KiB
BlitzBasic
SUMMARY = "A full-featured SSL VPN solution via tun device."
|
|
HOMEPAGE = "https://openvpn.net/"
|
|
SECTION = "net"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b76abd82c14ee01cc34c4ff5e3627b89"
|
|
DEPENDS = "lzo openssl iproute2 ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"
|
|
|
|
inherit autotools systemd update-rc.d
|
|
|
|
SRC_URI = "http://swupdate.openvpn.org/community/releases/${BP}.tar.gz \
|
|
file://openvpn \
|
|
file://openvpn@.service \
|
|
file://openvpn-volatile.conf"
|
|
|
|
UPSTREAM_CHECK_URI = "https://openvpn.net/community-downloads"
|
|
|
|
SRC_URI[sha256sum] = "333a7ef3d5b317968aca2c77bdc29aa7c6d6bb3316eb3f79743b59c53242ad3d"
|
|
|
|
# CVE-2020-7224 and CVE-2020-27569 are for Aviatrix OpenVPN client, not for openvpn.
|
|
CVE_CHECK_IGNORE += "CVE-2020-7224 CVE-2020-27569"
|
|
|
|
SYSTEMD_SERVICE:${PN} += "openvpn@loopback-server.service openvpn@loopback-client.service"
|
|
SYSTEMD_AUTO_ENABLE = "disable"
|
|
|
|
INITSCRIPT_PACKAGES = "${PN}"
|
|
INITSCRIPT_NAME:${PN} = "openvpn"
|
|
INITSCRIPT_PARAMS:${PN} = "start 10 2 3 4 5 . stop 70 0 1 6 ."
|
|
|
|
CFLAGS += "-fno-inline"
|
|
|
|
# I want openvpn to be able to read password from file (hrw)
|
|
EXTRA_OECONF += "--enable-iproute2"
|
|
EXTRA_OECONF += "${@bb.utils.contains('DISTRO_FEATURES', 'pam', '', '--disable-plugin-auth-pam', d)}"
|
|
|
|
# Explicitly specify IPROUTE to bypass the configure-time check for /sbin/ip on the host.
|
|
EXTRA_OECONF += "IPROUTE=${base_sbindir}/ip"
|
|
|
|
do_install:append() {
|
|
install -d ${D}/${sysconfdir}/init.d
|
|
install -m 755 ${WORKDIR}/openvpn ${D}/${sysconfdir}/init.d
|
|
|
|
install -d ${D}/${sysconfdir}/openvpn
|
|
install -d ${D}/${sysconfdir}/openvpn/sample
|
|
install -m 755 ${S}/sample/sample-config-files/loopback-server ${D}${sysconfdir}/openvpn/sample/loopback-server.conf
|
|
install -m 755 ${S}/sample/sample-config-files/loopback-client ${D}${sysconfdir}/openvpn/sample/loopback-client.conf
|
|
install -dm 755 ${D}${sysconfdir}/openvpn/sample/sample-keys
|
|
install -m 644 ${S}/sample/sample-keys/* ${D}${sysconfdir}/openvpn/sample/sample-keys
|
|
|
|
if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
|
|
install -d ${D}/${systemd_unitdir}/system
|
|
install -m 644 ${WORKDIR}/openvpn@.service ${D}/${systemd_unitdir}/system
|
|
install -m 644 ${WORKDIR}/openvpn@.service ${D}/${systemd_unitdir}/system/openvpn@loopback-server.service
|
|
install -m 644 ${WORKDIR}/openvpn@.service ${D}/${systemd_unitdir}/system/openvpn@loopback-client.service
|
|
|
|
install -d ${D}/${localstatedir}
|
|
install -d ${D}/${localstatedir}/lib
|
|
install -d -m 710 ${D}/${localstatedir}/lib/openvpn
|
|
|
|
install -d ${D}${sysconfdir}/tmpfiles.d
|
|
install -m 0644 ${WORKDIR}/openvpn-volatile.conf ${D}${sysconfdir}/tmpfiles.d/openvpn.conf
|
|
sed -i -e 's#@LOCALSTATEDIR@#${localstatedir}#g' ${D}${sysconfdir}/tmpfiles.d/openvpn.conf
|
|
fi
|
|
}
|
|
|
|
PACKAGES =+ " ${PN}-sample "
|
|
|
|
RRECOMMENDS:${PN} = "kernel-module-tun"
|
|
|
|
FILES:${PN}-dbg += "${libdir}/openvpn/plugins/.debug"
|
|
FILES:${PN} += "${systemd_unitdir}/system/openvpn@.service \
|
|
${sysconfdir}/tmpfiles.d \
|
|
"
|
|
FILES:${PN}-sample += "${systemd_unitdir}/system/openvpn@loopback-server.service \
|
|
${systemd_unitdir}/system/openvpn@loopback-client.service \
|
|
${sysconfdir}/openvpn/sample/"
|