mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-09-08 15:15:00 +02:00
43e39eb9c1
makefile-ptest.patch xmlsec1-examples-allow-build-in-separate-dir.patch refreshed for new version. Changelog: =========== Retired the XMLSec mailing list "xmlsec@aleksey.com" and the XMLSec Online Signature Verifier. Migration to OpenSSL 3.0 API (based on PR by @snargit). Note that OpenSSL engines are disabled by default when XMLSec library is compiled against OpenSSL 3.0. To re-enable OpenSSL engines, use "--enable-openssl3-engines" configure flag (there will be a lot of deprecation warnings). The OpenSSL before 1.1.0 and LibreSSL before 2.7.0 are now deprecated and will be removed in the future versions of XMLSec Library. Refactored all the integer casts to ensure cast-safety. Fixed all warnings and enabled "-Werror" and "-pedantic" flags on CI builds. Added configure flag to use size_t for xmlSecSize (currently disabled by default for backward compatibility). Moved all CI builds to GitHub actions. Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
68 lines
2.2 KiB
BlitzBasic
68 lines
2.2 KiB
BlitzBasic
SUMMARY = "XML Security Library is a C library based on LibXML2"
|
|
DESCRIPTION = "\
|
|
XML Security Library is a C library based on \
|
|
LibXML2 and OpenSSL. The library was created with a goal to support major \
|
|
XML security standards "XML Digital Signature" and "XML Encryption". \
|
|
"
|
|
HOMEPAGE = "http://www.aleksey.com/xmlsec/"
|
|
DEPENDS = "libtool libxml2 libxslt zlib"
|
|
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=352791d62092ea8104f085042de7f4d0"
|
|
|
|
SECTION = "libs"
|
|
|
|
SRC_URI = "http://www.aleksey.com/xmlsec/download/${BP}.tar.gz \
|
|
file://fix-ltmain.sh.patch \
|
|
file://change-finding-path-of-nss.patch \
|
|
file://makefile-ptest.patch \
|
|
file://xmlsec1-examples-allow-build-in-separate-dir.patch \
|
|
file://0001-nss-nspr-fix-for-multilib.patch \
|
|
file://run-ptest \
|
|
file://ensure-search-path-non-host.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "f0d97e008b211d85808f038326d42e7f5cf46648e176f07406a323e7e8d41c80"
|
|
|
|
inherit autotools-brokensep ptest pkgconfig
|
|
|
|
#CFLAGS += "-I${STAGING_INCDIR}/nss3"
|
|
#CPPFLAGS += "-I${STAGING_INCDIR}/nss3"
|
|
|
|
PACKAGECONFIG ??= "gnutls libgcrypt nss openssl des"
|
|
PACKAGECONFIG[gnutls] = ",,gnutls"
|
|
PACKAGECONFIG[libgcrypt] = ",,libgcrypt"
|
|
PACKAGECONFIG[nss] = "--with-nss=${STAGING_DIR_HOST} --with-nspr=${STAGING_DIR_HOST},--with-nss=no --with-nspr=no,nss nspr"
|
|
PACKAGECONFIG[openssl] = ",,openssl"
|
|
PACKAGECONFIG[des] = ",--disable-des,,"
|
|
|
|
# these can be dynamically loaded with xmlSecCryptoDLLoadLibrary()
|
|
FILES_SOLIBSDEV = "${libdir}/libxmlsec1.so"
|
|
FILES:${PN} += "${libdir}/libxmlsec1-*.so"
|
|
INSANE_SKIP:${PN} = "dev-so"
|
|
|
|
FILES:${PN}-dev += "${libdir}/xmlsec1Conf.sh"
|
|
FILES:${PN}-dbg += "${PTEST_PATH}/.debug/*"
|
|
|
|
RDEPENDS:${PN}-ptest += "${PN}-dev"
|
|
INSANE_SKIP:${PN}-ptest += "dev-deps"
|
|
|
|
PTEST_EXTRA_ARGS = "top_srcdir=${S} top_builddir=${B}"
|
|
|
|
do_compile_ptest () {
|
|
oe_runmake -C ${S}/examples ${PTEST_EXTRA_ARGS} all
|
|
}
|
|
|
|
do_install:append() {
|
|
for i in ${bindir}/xmlsec1-config ${libdir}/xmlsec1Conf.sh \
|
|
${libdir}/pkgconfig/xmlsec1-openssl.pc; do
|
|
sed -i -e "s@${RECIPE_SYSROOT}@@g" ${D}$i
|
|
done
|
|
}
|
|
|
|
do_install_ptest () {
|
|
oe_runmake -C ${S}/examples DESTDIR=${D}${PTEST_PATH} ${PTEST_EXTRA_ARGS} install-ptest
|
|
}
|
|
|
|
BBCLASSEXTEND = "native"
|