mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-09-17 20:51:57 +02:00
2913f7073f
HAVE_NODEJS is a leftover from meta-refkit-core where the layer had to adapt to different BBLAYER combinations (some where nodejs wasn't available but mraa/upm were). mraa/upm nodejs bindings currently fail to build (due to a problem in swig with nodejs > v7.x) so we keep them disabled until a newer version of swig lands in OE-core. The commit adds BINDINGS overrides for armv4/5 to remind that nodejs isn't available on those architectures. Signed-off-by: Mikko Ylinen <mikko.ylinen@linux.intel.com> Signed-off-by: Armin Kuster <akuster808@gmail.com>
52 lines
1.7 KiB
BlitzBasic
52 lines
1.7 KiB
BlitzBasic
SUMMARY = "Sensor/Actuator repository for Mraa"
|
|
HOMEPAGE = "https://github.com/intel-iot-devkit/upm"
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=66493d54e65bfc12c7983ff2e884f37f"
|
|
|
|
DEPENDS = "libjpeg-turbo mraa"
|
|
|
|
SRCREV = "106b6c706268522ab0168a4ddb19e89ce832e084"
|
|
PV = "1.3.0-git${SRCPV}"
|
|
|
|
SRC_URI = " \
|
|
git://github.com/intel-iot-devkit/${BPN}.git;protocol=http \
|
|
file://ads1x15-fixed-case-logic-in-getThresh-function.patch \
|
|
"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
# Depends on mraa which only supports x86 and ARM for now
|
|
COMPATIBLE_HOST = "(x86_64.*|i.86.*|aarch64.*|arm.*)-linux"
|
|
|
|
inherit distutils3-base cmake
|
|
|
|
|
|
# override this in local.conf to get needed bindings.
|
|
# BINDINGS_pn-upm="python"
|
|
# will result in only the python bindings being built/packaged.
|
|
# Note: 'nodejs' is disabled by default because the bindings
|
|
# generation currently fails with nodejs (>v7.x).
|
|
BINDINGS ??= "python"
|
|
|
|
# nodejs isn't available for armv4/armv5 architectures
|
|
BINDINGS_armv4 ??= "python"
|
|
BINDINGS_armv5 ??= "python"
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.contains('PACKAGES', 'node-${PN}', 'nodejs', '', d)} \
|
|
${@bb.utils.contains('PACKAGES', '${PYTHON_PN}-${PN}', 'python', '', d)}"
|
|
|
|
PACKAGECONFIG[python] = "-DBUILDSWIGPYTHON=ON, -DBUILDSWIGPYTHON=OFF, swig-native ${PYTHON_PN},"
|
|
PACKAGECONFIG[nodejs] = "-DBUILDSWIGNODE=ON, -DBUILDSWIGNODE=OFF, swig-native nodejs-native,"
|
|
|
|
FILES_${PYTHON_PN}-${PN} = "${PYTHON_SITEPACKAGES_DIR}"
|
|
RDEPENDS_${PYTHON_PN}-${PN} += "${PYTHON_PN}"
|
|
|
|
FILES_node-${PN} = "${prefix}/lib/node_modules/"
|
|
RDEPENDS_node-${PN} += "nodejs"
|
|
|
|
### Include desired language bindings ###
|
|
PACKAGES =+ "${@bb.utils.contains('BINDINGS', 'nodejs', 'node-${PN}', '', d)}"
|
|
PACKAGES =+ "${@bb.utils.contains('BINDINGS', 'python', '${PYTHON_PN}-${PN}', '', d)}"
|