mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-09-16 12:12:16 +02:00
740a9b250c
Changelog:
==========
Notewhorth changes:
-------------------
Backported #8252: Support sending server redirection PDU
Backported #8406: Ensure X11 client cursor is never smaller 1x1
Backported #8403: Fixed multiple client side input validation issues
(CVE-2022-39316, CVE-2022-39317, CVE-2022-39318, CVE-2022-39319,
CVE-2022-39320, CVE-2022-41877, CVE-2022-39347)
Backported #7282: Proxy server now discards input events sent before
activation was received
Backported #8324: Internal replacements for md4, md5 and hmac-md5
For the time being the RDP protocol requires these outdated hash
algorithms. So any distribution that wants to ship a working
FreeRDP should check the options WITH_INTERNAL_MD4 (and depending
on OpenSSL deprecation status WITH_INTERNAL_MD5)
Fixed issues:
--------------
Backported #8341: Null checks in winpr_Digest_Free
Backported #8335: Missing NULL return in winpr_Digest_New
Backported #8192: Support for audin version 2 microphone channel
Backported #7282: Discard input events before activation (Fixes #8374)
Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
86 lines
3.1 KiB
BlitzBasic
86 lines
3.1 KiB
BlitzBasic
# Copyright (C) 2010-2012 O.S. Systems Software Ltda. All Rights Reserved
|
|
# Released under the MIT license
|
|
|
|
DESCRIPTION = "FreeRDP RDP client & server library"
|
|
HOMEPAGE = "http://www.freerdp.com"
|
|
DEPENDS = "openssl alsa-lib libusb1"
|
|
SECTION = "net"
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"
|
|
|
|
inherit pkgconfig cmake gitpkgv
|
|
|
|
PE = "1"
|
|
PKGV = "${GITPKGVTAG}"
|
|
|
|
SRCREV = "fa8e1b1c765a4466030ac52240f052c0b440a4d1"
|
|
SRC_URI = "git://github.com/FreeRDP/FreeRDP.git;branch=stable-2.0;protocol=https \
|
|
file://winpr-makecert-Build-with-install-RPATH.patch \
|
|
"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
EXTRA_OECMAKE += " \
|
|
-DWITH_ALSA=ON \
|
|
-DWITH_FFMPEG=OFF \
|
|
-DWITH_CUNIT=OFF \
|
|
-DWITH_NEON=OFF \
|
|
-DBUILD_STATIC_LIBS=OFF \
|
|
-DCMAKE_POSITION_INDEPENDANT_CODE=ON \
|
|
-DWITH_MANPAGES=OFF \
|
|
"
|
|
|
|
PACKAGECONFIG ??= " \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'directfb pam pulseaudio wayland x11', d)}\
|
|
gstreamer cups pcsc \
|
|
"
|
|
|
|
X11_DEPS = "virtual/libx11 libxinerama libxext libxcursor libxv libxi libxrender libxfixes libxdamage libxrandr libxkbfile"
|
|
PACKAGECONFIG[x11] = "-DWITH_X11=ON -DWITH_XINERAMA=ON -DWITH_XEXT=ON -DWITH_XCURSOR=ON -DWITH_XV=ON -DWITH_XI=ON -DWITH_XRENDER=ON -DWITH_XFIXES=ON -DWITH_XDAMAGE=ON -DWITH_XRANDR=ON -DWITH_XKBFILE=ON,-DWITH_X11=OFF,${X11_DEPS}"
|
|
PACKAGECONFIG[wayland] = "-DWITH_WAYLAND=ON,-DWITH_WAYLAND=OFF,wayland wayland-native libxkbcommon"
|
|
PACKAGECONFIG[directfb] = "-DWITH_DIRECTFB=ON,-DWITH_DIRECTFB=OFF,directfb"
|
|
PACKAGECONFIG[pam] = "-DWITH_PAM=ON,-DWITH_PAM=OFF,libpam"
|
|
PACKAGECONFIG[pcsc] = "-DWITH_PCSC=ON,-DWITH_PCSC=OFF,pcsc-lite"
|
|
PACKAGECONFIG[pulseaudio] = "-DWITH_PULSEAUDIO=ON,-DWITH_PULSEAUDIO=OFF,pulseaudio"
|
|
PACKAGECONFIG[gstreamer] = "-DWITH_GSTREAMER_1_0=ON,-DWITH_GSTREAMER_1_0=OFF,gstreamer1.0 gstreamer1.0-plugins-base"
|
|
PACKAGECONFIG[cups] = "-DWITH_CUPS=ON,-DWITH_CUPS=OFF,cups"
|
|
|
|
PACKAGES =+ "libfreerdp"
|
|
|
|
LEAD_SONAME = "libfreerdp.so"
|
|
FILES:libfreerdp = "${libdir}/lib*${SOLIBS}"
|
|
|
|
PACKAGES_DYNAMIC += "^libfreerdp-plugin-.*"
|
|
|
|
# we will need winpr-makecert to generate TLS certificates
|
|
do_install:append () {
|
|
install -d ${D}${bindir}
|
|
install -m755 winpr/tools/makecert-cli/winpr-makecert ${D}${bindir}
|
|
rm -rf ${D}${libdir}/cmake
|
|
rm -rf ${D}${libdir}/freerdp
|
|
}
|
|
|
|
python populate_packages:prepend () {
|
|
freerdp_root = d.expand('${libdir}/freerdp')
|
|
|
|
do_split_packages(d, freerdp_root, r'^(audin_.*)\.so$',
|
|
output_pattern='libfreerdp-plugin-%s',
|
|
description='FreeRDP plugin %s',
|
|
prepend=True, extra_depends='libfreerdp-plugin-audin')
|
|
|
|
do_split_packages(d, freerdp_root, r'^(rdpsnd_.*)\.so$',
|
|
output_pattern='libfreerdp-plugin-%s',
|
|
description='FreeRDP plugin %s',
|
|
prepend=True, extra_depends='libfreerdp-plugin-rdpsnd')
|
|
|
|
do_split_packages(d, freerdp_root, r'^(tsmf_.*)\.so$',
|
|
output_pattern='libfreerdp-plugin-%s',
|
|
description='FreeRDP plugin %s',
|
|
prepend=True, extra_depends='libfreerdp-plugin-tsmf')
|
|
|
|
do_split_packages(d, freerdp_root, r'^([^-]*)\.so$',
|
|
output_pattern='libfreerdp-plugin-%s',
|
|
description='FreeRDP plugin %s',
|
|
prepend=True, extra_depends='')
|
|
}
|