mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-09-16 12:12:16 +02:00
33086407b1
0001-doveadm-Fix-parallel-build.patch removed since it is included in 2.3.13 refresh 0001-configure.ac-convert-AC_TRY_RUN-to-AC_TRY_LINK-state.patch add 0001-not-check-pandoc.patch to not check pandoc of configure Signed-off-by: Wang Mingyu <wangmy@cn.fujitsu.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
74 lines
3.2 KiB
BlitzBasic
74 lines
3.2 KiB
BlitzBasic
SUMMARY = "Dovecot is an open source IMAP and POP3 email server"
|
|
HOMEPAGE = "https://www.dovecot.org/"
|
|
DESCRIPTION = "Dovecot is an open source IMAP and POP3 email server for Linux/UNIX-like systems, written with security primarily in mind. Dovecot is an excellent choice for both small and large installations. It's fast, simple to set up, requires no special administration and it uses very little memory."
|
|
SECTION = "mail"
|
|
LICENSE = "LGPLv2.1 & MIT"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=2956560272e5b31d9d64f03111732048"
|
|
|
|
SRC_URI = "http://dovecot.org/releases/2.3/dovecot-${PV}.tar.gz \
|
|
file://0001-configure.ac-convert-AC_TRY_RUN-to-AC_TRY_LINK-state.patch \
|
|
file://dovecot.service \
|
|
file://dovecot.socket \
|
|
file://0001-not-check-pandoc.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "f512bf1a4dac9ac994fddfb6bc5068ff"
|
|
SRC_URI[sha256sum] = "a3f875b80ec11a452480690108660030978c94fa8e796ad6d943a874b496f1c4"
|
|
|
|
DEPENDS = "openssl xz zlib bzip2 libcap icu libtirpc bison-native"
|
|
CFLAGS += "-I${STAGING_INCDIR}/tirpc"
|
|
LDFLAGS += "-ltirpc"
|
|
|
|
inherit autotools pkgconfig systemd useradd gettext
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'ldap pam', d)}"
|
|
|
|
PACKAGECONFIG[pam] = "--with-pam,--without-pam,libpam,"
|
|
PACKAGECONFIG[ldap] = "--with-ldap=plugin,--without-ldap,openldap,"
|
|
PACKAGECONFIG[lz4] = "--with-lz4,--without-lz4,lz4,"
|
|
|
|
# From native build in armv7a-hf/eglibc
|
|
CACHED_CONFIGUREVARS += "i_cv_signed_size_t=no \
|
|
i_cv_gmtime_max_time_t=32 \
|
|
i_cv_signed_time_t=yes \
|
|
i_cv_mmap_plays_with_write=yes \
|
|
i_cv_fd_passing=yes \
|
|
i_cv_c99_vsnprintf=yes \
|
|
lib_cv___va_copy=yes \
|
|
lib_cv_va_copy=yes \
|
|
lib_cv_va_val_copy=yes \
|
|
"
|
|
|
|
# hardcode epoll() to avoid running unsafe tests
|
|
# BSD needs kqueue and uclibc poll()
|
|
EXTRA_OECONF = " --with-ioloop=epoll \
|
|
--with-systemdsystemunitdir=${systemd_unitdir}/system"
|
|
|
|
# Uses hidden symbols
|
|
# libssl_iostream_openssl.so: undefined reference to `ssl_iostream_handshake'
|
|
LTO = ""
|
|
|
|
SYSTEMD_PACKAGES = "${PN}"
|
|
SYSTEMD_SERVICE_${PN} = "dovecot.service dovecot.socket"
|
|
SYSTEMD_AUTO_ENABLE = "disable"
|
|
|
|
do_install_append () {
|
|
install -d 755 ${D}/etc/dovecot
|
|
touch 644 ${D}/etc/dovecot/dovecot.conf
|
|
install -m 0644 ${WORKDIR}/dovecot.service ${D}${systemd_unitdir}/system
|
|
sed -i -e 's#@SYSCONFDIR@#${sysconfdir}#g' ${D}${systemd_unitdir}/system/dovecot.service
|
|
sed -i -e 's#@SBINDIR@#${sbindir}#g' ${D}${systemd_unitdir}/system/dovecot.service
|
|
}
|
|
|
|
USERADD_PACKAGES = "${PN}"
|
|
USERADD_PARAM_${PN} = "-r -d ${libexecdir} -M -s ${base_sbindir}/nologin -g dovecot dovecot; \
|
|
-r -d ${libexecdir} -M -s ${base_sbindir}/nologin -g dovenull dovenull"
|
|
GROUPADD_PARAM_${PN} = "-f -r dovecot;-f -r dovenull"
|
|
|
|
FILES_${PN} += "${libdir}/dovecot/*plugin.so \
|
|
${libdir}/dovecot/libfs_compress.so \
|
|
${libdir}/dovecot/libssl_iostream_openssl.so"
|
|
FILES_${PN}-staticdev += "${libdir}/dovecot/*/*.a"
|
|
FILES_${PN}-dev += "${libdir}/dovecot/libdovecot*.so"
|
|
FILES_${PN}-dbg += "${libdir}/dovecot/*/.debug"
|