mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-09-16 20:21:58 +02:00
d830e7901e
* also log.do_configure is showing this since switch to python3:
DEBUG: Executing shell function do_configure
File "<string>", line 1
import sys ; print sys.version[0:3]
^
SyntaxError: invalid syntax
and this whole line doesn't make much sense and PY_VERSION shouldn't be used in configure.ac since:
commit 9087a59b1c
Author: Martin Jansa <Martin.Jansa@gmail.com>
Date: Thu May 5 16:58:59 2016 +0200
pidgin: use pkg-config instead of hardcoded paths or python-config
* use separate recipe for libgnt (needed only when consoleui PACKAGECONFIG is enabled)
with 0.14.0 release libgnt was moved to separate repository
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
113 lines
4.8 KiB
BlitzBasic
113 lines
4.8 KiB
BlitzBasic
SUMMARY = "multi-protocol instant messaging client"
|
|
|
|
SECTION = "x11/network"
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
|
|
DEPENDS = "python3 virtual/libintl intltool-native libxml2 gconf glib-2.0-native"
|
|
|
|
inherit autotools gettext pkgconfig gconf perlnative python3native
|
|
|
|
SRC_URI = "\
|
|
${SOURCEFORGE_MIRROR}/pidgin/pidgin-${PV}.tar.bz2 \
|
|
file://sanitize-configure.ac.patch \
|
|
file://purple-OE-branding-25.patch \
|
|
file://0001-configure.ac-fix-build-with-autoconf-2.71.patch \
|
|
file://0002-configure.ac-disable-few-languages-not-compatible-wi.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "f132e18d551117d9e46acce29ba4f40892a86746c366999166a3862b51060780"
|
|
|
|
PACKAGECONFIG ??= "gnutls consoleui avahi dbus idn nss \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11 gtk startup-notification', '', d)} \
|
|
"
|
|
PACKAGECONFIG[farsight2] = "--enable-farstream,--disable-farstream,farsight2"
|
|
# --disable-gstreamer compile without GStreamer audio support
|
|
# --disable-gstreamer-video
|
|
# compile without GStreamer 1.0 Video Overlay support
|
|
# --disable-gstreamer-interfaces
|
|
# compile without GStreamer 0.10 interface support
|
|
# --with-gstreamer=<version>
|
|
# compile with GStreamer 0.10 or 1.0 interface
|
|
PACKAGECONFIG[gstreamer] = "--enable-gstreamer,--disable-gstreamer,gstreamer"
|
|
PACKAGECONFIG[vv] = "--enable-vv,--disable-vv,gstreamer"
|
|
PACKAGECONFIG[idn] = "--enable-idn,--disable-idn,libidn"
|
|
PACKAGECONFIG[gtk] = "--enable-gtkui,--disable-gtkui,gtk+"
|
|
PACKAGECONFIG[x11] = "--with-x=yes --x-includes=${STAGING_INCDIR} --x-libraries=${STAGING_LIBDIR},--with-x=no,virtual/libx11"
|
|
PACKAGECONFIG[startup-notification] = "--enable-startup-notification,--disable-startup-notification,startup-notification"
|
|
PACKAGECONFIG[consoleui] = "--enable-consoleui --with-ncurses-headers=${STAGING_INCDIR},--disable-consoleui,libgnt"
|
|
PACKAGECONFIG[gnutls] = "--enable-gnutls --with-gnutls-includes=${STAGING_INCDIR} --with-gnutls-libs=${STAGING_LIBDIR},--disable-gnutls,gnutls,libpurple-plugin-ssl-gnutls"
|
|
PACKAGECONFIG[dbus] = "--enable-dbus,--disable-dbus,dbus dbus-glib"
|
|
PACKAGECONFIG[avahi] = "--enable-avahi,--disable-avahi,avahi"
|
|
PACKAGECONFIG[nss] = "--enable-nss,--disable-nss,nss nspr,libpurple-plugin-ssl-nss"
|
|
|
|
EXTRA_OECONF = " \
|
|
--with-python=python3 \
|
|
--disable-perl \
|
|
--disable-tcl \
|
|
--disable-gevolution \
|
|
--disable-schemas-install \
|
|
--disable-gtkspell \
|
|
--disable-meanwhile \
|
|
--disable-nm \
|
|
--disable-screensaver \
|
|
"
|
|
|
|
OE_LT_RPATH_ALLOW=":${libdir}/purple-2:"
|
|
OE_LT_RPATH_ALLOW[export]="1"
|
|
|
|
PACKAGES =+ "libpurple-dev libpurple finch finch-dev ${PN}-data"
|
|
|
|
RPROVIDES_${PN}-dbg += "libpurple-dbg finch-dbg"
|
|
|
|
LEAD_SONAME = "libpurple.so.0"
|
|
FILES_libpurple = "${libdir}/libpurple*.so.* ${libdir}/purple-2 ${bindir}/purple-* ${sysconfdir}/gconf/schemas/purple* ${datadir}/purple/ca-certs"
|
|
FILES_libpurple-dev = "${libdir}/libpurple*.la \
|
|
${libdir}/libpurple*.so \
|
|
${libdir}/purple-2/*.la \
|
|
${libdir}/purple-2/libjabber.so \
|
|
${libdir}/purple-2/liboscar.so \
|
|
${libdir}/purple-2/libymsg.so \
|
|
${datadir}/aclocal"
|
|
FILES_finch = "${bindir}/finch"
|
|
FILES_finch-dev = "${libdir}/finch/*.la"
|
|
|
|
FILES_${PN} = "${bindir} ${datadir}/${PN} ${libdir}/${PN}/*.so \
|
|
${datadir}/applications"
|
|
RRECOMMENDS_${PN} = "${PN}-data libpurple-protocol-irc libpurple-protocol-xmpp"
|
|
|
|
FILES_${PN}-data = "${datadir}/pixmaps ${datadir}/sounds ${datadir}/icons ${datadir}/appdata"
|
|
FILES_${PN}-dev += "${libdir}/${PN}/*.la"
|
|
|
|
PACKAGES_DYNAMIC += "^libpurple-protocol-.* ^libpurple-plugin-.* ^pidgin-plugin-.* ^finch-plugin-.*"
|
|
|
|
python populate_packages_prepend () {
|
|
pidgroot = d.expand('${libdir}/pidgin')
|
|
purple = d.expand('${libdir}/purple-2')
|
|
finch = d.expand('${libdir}/finch')
|
|
|
|
do_split_packages(d, pidgroot, '^([^l][^i][^b].*)\.so$',
|
|
output_pattern='pidgin-plugin-%s',
|
|
description='Pidgin plugin %s',
|
|
prepend=True, extra_depends='')
|
|
|
|
do_split_packages(d, purple, '^lib(.*)\.so$',
|
|
output_pattern='libpurple-protocol-%s',
|
|
description='Libpurple protocol plugin for %s',
|
|
prepend=True, extra_depends='')
|
|
|
|
do_split_packages(d, purple, '^(ssl-.*)\.so$',
|
|
output_pattern='libpurple-plugin-%s',
|
|
description='libpurple plugin %s',
|
|
prepend=True, extra_depends='libpurple-plugin-ssl')
|
|
|
|
do_split_packages(d, purple, '^([^l][^i][^b].*)\.so$',
|
|
output_pattern='libpurple-plugin-%s',
|
|
description='libpurple plugin %s',
|
|
prepend=True, extra_depends='')
|
|
|
|
do_split_packages(d, finch, '^([^l][^i][^b].*)\.so$',
|
|
output_pattern='finch-plugin-%s',
|
|
description='Finch plugin %s',
|
|
prepend=True, extra_depends='')
|
|
}
|