mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-09-16 12:12:16 +02:00
7a44ad2c84
3.34.5 ====== * Leave overview when locking the screen [Jonas D.; !1043] * Avoid IO on the main thread [Christian; !1050] * Fix OSK layout fallback for unsupported variants [Florian; #2471] * Fix high-contrast/symbolic icon mix-up [Florian; #2414] * Misc. bug fixes and cleanups [Jonas Ã…., Florian; !1032, #2386] Contributors: Jonas Dreßler, Christian Hergert, Florian Müllner, Jwtiyar Nariman, Jonas Ã…dahl Translators: Jwtiyar Nariman [ckb] Signed-off-by: Andreas Müller <schnitzeltony@gmail.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
65 lines
1.8 KiB
BlitzBasic
65 lines
1.8 KiB
BlitzBasic
SUMMARY = "GNOME Shell is the graphical shell of the GNOME desktop environment"
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
|
|
GNOMEBASEBUILDCLASS = "meson"
|
|
|
|
inherit gnomebase gsettings gettext gobject-introspection features_check upstream-version-is-even bash-completion
|
|
|
|
REQUIRED_DISTRO_FEATURES = "x11 polkit systemd pam"
|
|
|
|
DEPENDS = " \
|
|
libxml2-native \
|
|
sassc-native \
|
|
gtk+3 \
|
|
mutter \
|
|
evolution-data-server \
|
|
gcr \
|
|
gjs \
|
|
gnome-autoar \
|
|
polkit \
|
|
libcroco \
|
|
startup-notification \
|
|
ibus \
|
|
gsettings-desktop-schemas \
|
|
"
|
|
|
|
GTKDOC_MESON_OPTION = "gtk_doc"
|
|
|
|
# gobject-introspection is mandatory and cannot be configured
|
|
REQUIRED_DISTRO_FEATURES += "gobject-introspection-data"
|
|
UNKNOWN_CONFIGURE_WHITELIST_append = " introspection"
|
|
|
|
SRC_URI[archive.md5sum] = "4bd27c8a91d30fde78cb69b94677cf1f"
|
|
SRC_URI[archive.sha256sum] = "d296f318a74a6d7883358a6ce1c4d8808b7903dbbb4f9c61ab4230f18e6d7550"
|
|
|
|
PACKAGECONFIG ??= "bluetooth nm ${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}"
|
|
PACKAGECONFIG[bluetooth] = ",,gnome-bluetooth"
|
|
PACKAGECONFIG[nm] = "-Dnetworkmanager=true, -Dnetworkmanager=false, networkmanager"
|
|
PACKAGECONFIG[systemd] = "-Dsystemd=true, -Dsystemd=false, systemd"
|
|
|
|
EXTRA_OEMESON = " \
|
|
-Dman=false \
|
|
"
|
|
|
|
do_install_append() {
|
|
# fix shebangs
|
|
for tool in `find ${D}${bindir} -name '*-tool'`; do
|
|
sed -i 's:#!${PYTHON}:#!${bindir}/${PYTHON_PN}:' $tool
|
|
done
|
|
}
|
|
|
|
FILES_${PN} += " \
|
|
${datadir}/dbus-1 \
|
|
${datadir}/gnome-control-center \
|
|
${datadir}/xdg-desktop-portal \
|
|
${systemd_user_unitdir} \
|
|
"
|
|
|
|
RDEPENDS_${PN} += "gsettings-desktop-schemas gdm-base librsvg-gtk"
|
|
|
|
PACKAGES =+ "${PN}-tools"
|
|
FILES_${PN}-tools = "${bindir}/*-tool"
|
|
RDEPENDS_${PN}-tools = "python3-core"
|
|
|