mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-08-15 17:28:04 +02:00
d8fffe3c07
Remove patches applied upstream. pkg-config is now used when checking for freetype. The licence did not change by the changes to COPYING. Signed-off-by: Adrian Bunk <bunk@stusta.de> Signed-off-by: Khem Raj <raj.khem@gmail.com>
113 lines
2.4 KiB
BlitzBasic
113 lines
2.4 KiB
BlitzBasic
SUMMARY = "F Virtual Window Manager "
|
|
HOMEPAGE = "http://www.fvwm.org/"
|
|
SECTION = "x11/wm"
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=f8204787357db6ea518dcc9b6cf08388"
|
|
|
|
DEPENDS = " \
|
|
bison-native \
|
|
flex-native \
|
|
freetype-native \
|
|
gettext-native \
|
|
libxslt-native \
|
|
fontconfig \
|
|
libice \
|
|
libpng \
|
|
librsvg \
|
|
libsm \
|
|
libxau \
|
|
libxcb \
|
|
libxcursor \
|
|
libxdmcp \
|
|
libxext \
|
|
libxfixes \
|
|
libxft \
|
|
libxinerama \
|
|
libxml2 \
|
|
libxrender \
|
|
libxt \
|
|
virtual/libx11 \
|
|
xrandr \
|
|
zlib \
|
|
"
|
|
|
|
PV = "2.6.8"
|
|
|
|
SRC_URI = " \
|
|
git://github.com/fvwmorg/fvwm.git;protocol=https \
|
|
file://0001-Fix-compilation-for-disabled-gnome.patch \
|
|
"
|
|
|
|
SRCREV = "dc6a396bfe5cd6c53eb1df103c3af505d0899f90"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools gettext update-alternatives pkgconfig pythonnative perlnative distro_features_check
|
|
# depends on virtual/libx11
|
|
REQUIRED_DISTRO_FEATURES = "x11"
|
|
|
|
ALTERNATIVE_${PN} = "x-window-manager"
|
|
ALTERNATIVE_TARGET[x-window-manager] = "${bindir}/fvwm"
|
|
ALTERNATIVE_PRIORITY[x-window-manager] = "20"
|
|
|
|
EXTRA_OECONF = " \
|
|
--disable-bidi \
|
|
--disable-fontconfigtest \
|
|
--disable-htmldoc \
|
|
--disable-imlibtest \
|
|
--disable-mandoc \
|
|
--disable-nls \
|
|
--disable-perllib \
|
|
--disable-rsvg \
|
|
--disable-shape \
|
|
--disable-sm \
|
|
--disable-xfttest \
|
|
--with-imlib-exec-prefix=/nonexistent \
|
|
--with-imlib-prefix=/nonexistent \
|
|
--without-ncurses-library \
|
|
--without-readline-library \
|
|
--without-rplay-library \
|
|
--without-stroke-library \
|
|
--without-termcap-library \
|
|
--without-xpm-library \
|
|
ac_cv_func_mkstemp=no \
|
|
has_safety_mkstemp=yes \
|
|
"
|
|
|
|
# show the exact commands in the log file
|
|
EXTRA_OEMAKE = " \
|
|
V=1 \
|
|
"
|
|
|
|
do_install_append() {
|
|
install -d -m 0755 ${D}/${sysconfdir}/xdg/fvwm
|
|
# You can install the config file here
|
|
|
|
install -d -m 0755 ${D}/${datadir}/fvwm
|
|
touch ${D}/${datadir}/fvwm/ConfigFvwmDefaults
|
|
}
|
|
|
|
# the only needed packages (note: locale packages are automatically generated
|
|
# as well)
|
|
PACKAGES = " \
|
|
${PN} \
|
|
${PN}-dbg \
|
|
"
|
|
|
|
# minimal set of binaries
|
|
FILES_${PN} = " \
|
|
${bindir}/fvwm \
|
|
${bindir}/fvwm-root \
|
|
${datadir}/fvwm/ConfigFvwmDefaults \
|
|
"
|
|
|
|
RDEPENDS_${PN} = " \
|
|
xuser-account \
|
|
"
|
|
|
|
# by default a lot of stuff is installed and it's not easy to control what to
|
|
# install, so install everything, but skip the check
|
|
INSANE_SKIP_${PN} = " \
|
|
installed-vs-shipped \
|
|
"
|