mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-09-16 12:12:16 +02:00
a07c969aeb
It is detecting cross compile badness for -lexpat since the check finds it on build host, so aide the build ssytem to find it in staging sysroot Disable internal ltdl, use libtool provided one Define defines to indicate that platform has ssize_t and long_double Disable java,r,c-sharp, as it is unused Arrange source URIs before checksums gtk-doc is not needed, morever it ends up in unknown configure options Signed-off-by: Khem Raj <raj.khem@gmail.com>
60 lines
1.9 KiB
BlitzBasic
60 lines
1.9 KiB
BlitzBasic
SUMMARY = "Graph Visualization Tools"
|
|
HOMEPAGE = "http://www.graphviz.org"
|
|
LICENSE = "EPL-1.0"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=9109f5fc16cf963fb3cdd32781b3ce04"
|
|
|
|
DEPENDS = " \
|
|
intltool-native \
|
|
bison-native \
|
|
groff-native \
|
|
libtool \
|
|
gdk-pixbuf \
|
|
librsvg \
|
|
cairo \
|
|
pango \
|
|
expat \
|
|
freetype \
|
|
"
|
|
DEPENDS_append_class-target = " ${BPN}-native"
|
|
|
|
inherit autotools-brokensep pkgconfig gettext
|
|
|
|
# The source tarball suggested at
|
|
# https://graphviz.gitlab.io/_pages/Download/Download_source.html has no
|
|
# version in its name. So once graphviz is updgraded, only first time users will
|
|
# get checksum errors. Fedora people seem to expect same so they use a versioned
|
|
# source - see https://src.fedoraproject.org/cgit/rpms/graphviz.git/tree/graphviz.spec
|
|
|
|
SRC_URI = "https://gitlab.com/graphviz/graphviz/-/archive/stable_release_${PV}/graphviz-stable_release_${PV}.tar.gz \
|
|
"
|
|
# Use native mkdefs
|
|
SRC_URI_append_class-target = " file://0001-Use-native-mkdefs.patch"
|
|
SRC_URI[md5sum] = "2acf30ca8e6cc8b001b0334db65fd072"
|
|
SRC_URI[sha256sum] = "e6c3f8dbfde1c4523055403927bef29f97f9fc12715c1042b5dcf648a2c1c62a"
|
|
|
|
S = "${WORKDIR}/${BPN}-stable_release_${PV}"
|
|
|
|
EXTRA_OECONF_class-target = "\
|
|
--with-expatincludedir=${STAGING_INCDIR} \
|
|
--with-expatlibdir=${STAGING_LIBDIR} \
|
|
--without-included-ltdl \
|
|
--disable-java \
|
|
--disable-r \
|
|
--disable-sharp \
|
|
"
|
|
CFLAGS_append_class-target = " -D_typ_ssize_t=1 -D_long_double=1"
|
|
do_configure_prepend() {
|
|
cd ${S}
|
|
# create version.m4 and ignore libtoolize errors
|
|
./autogen.sh NOCONFIG || true
|
|
}
|
|
|
|
do_install_append_class-native() {
|
|
# install mkdefs for target build
|
|
install -m755 ${B}/lib/gvpr/mkdefs ${D}${bindir}
|
|
}
|
|
|
|
FILES_SOLIBSDEV_append = " ${libdir}/graphviz/lib*${SOLIBSDEV}"
|
|
|
|
BBCLASSEXTEND = "native"
|