mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-09-17 04:31:56 +02:00
c48feb5f18
Upgrade urgency: SECURITY, contains fixes to security issues. Security Fixes: (CVE-2021-41099) Integer to heap buffer overflow handling certain string commands and network payloads, when proto-max-bulk-len is manually configured to a non-default, very large value [reported by yiyuaner]. (CVE-2021-32762) Integer to heap buffer overflow issue in redis-cli and redis-sentinel parsing large multi-bulk replies on some older and less common platforms [reported by Microsoft Vulnerability Research]. (CVE-2021-32687) Integer to heap buffer overflow with intsets, when set-max-intset-entries is manually configured to a non-default, very large value [reported by Pawel Wieczorkiewicz, AWS]. (CVE-2021-32675) Denial Of Service when processing RESP request payloads with a large number of elements on many connections. (CVE-2021-32672) Random heap reading issue with Lua Debugger [reported by Meir Shpilraien]. (CVE-2021-32628) Integer to heap buffer overflow handling ziplist-encoded data types, when configuring a large, non-default value for hash-max-ziplist-entries, hash-max-ziplist-value, zset-max-ziplist-entries or zset-max-ziplist-value [reported by sundb]. (CVE-2021-32627) Integer to heap buffer overflow issue with streams, when configuring a non-default, large value for proto-max-bulk-len and client-query-buffer-limit [reported by sundb]. (CVE-2021-32626) Specially crafted Lua scripts may result with Heap buffer overflow [reported by Meir Shpilraien]. Bug fixes that involve behavior changes: GEO* STORE with empty source key deletes the destination key and return 0 (#9271) Previously it would have returned an empty array like the non-STORE variant. PUBSUB NUMPAT replies with number of patterns rather than number of subscriptions (#9209) This actually changed in 6.2.0 but was overlooked and omitted from the release notes. Bug fixes that are only applicable to previous releases of Redis 6.2: Fix CLIENT PAUSE, used an old timeout from previous PAUSE (#9477) Fix CLIENT PAUSE in a replica would mess the replication offset (#9448) Add some missing error statistics in INFO errorstats (#9328) Other bug fixes: Fix incorrect reply of COMMAND command key positions for MIGRATE command (#9455) Fix appendfsync to always guarantee fsync before reply, on MacOS and FreeBSD (kqueue) (#9416) Fix the wrong mis-detection of sync_file_range system call, affecting performance (#9371) CLI tools: When redis-cli received ASK response, it didn't handle it (#8930) Improvements: Add latency monitor sample when key is deleted via lazy expire (#9317) Sanitize corrupt payload improvements (#9321, #9399) Delete empty keys when loading RDB file or handling a RESTORE command (#9297, #9349) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
67 lines
2.3 KiB
BlitzBasic
67 lines
2.3 KiB
BlitzBasic
SUMMARY = "Redis key-value store"
|
|
DESCRIPTION = "Redis is an open source, advanced key-value store."
|
|
HOMEPAGE = "http://redis.io"
|
|
SECTION = "libs"
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=8ffdd6c926faaece928cf9d9640132d2"
|
|
DEPENDS = "readline lua ncurses"
|
|
|
|
SRC_URI = "http://download.redis.io/releases/${BP}.tar.gz \
|
|
file://redis.conf \
|
|
file://init-redis-server \
|
|
file://redis.service \
|
|
file://hiredis-use-default-CC-if-it-is-set.patch \
|
|
file://lua-update-Makefile-to-use-environment-build-setting.patch \
|
|
file://oe-use-libc-malloc.patch \
|
|
file://0001-src-Do-not-reset-FINAL_LIBS.patch \
|
|
file://GNU_SOURCE.patch \
|
|
file://0006-Define-correct-gregs-for-RISCV32.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "5b2b8b7a50111ef395bf1c1d5be11e6e167ac018125055daa8b5c2317ae131ab"
|
|
|
|
inherit autotools-brokensep update-rc.d systemd useradd
|
|
|
|
FINAL_LIBS:x86:toolchain-clang = "-latomic"
|
|
FINAL_LIBS:riscv32:toolchain-clang = "-latomic"
|
|
FINAL_LIBS:mips = "-latomic"
|
|
FINAL_LIBS:arm = "-latomic"
|
|
FINAL_LIBS:powerpc = "-latomic"
|
|
|
|
export FINAL_LIBS
|
|
|
|
USERADD_PACKAGES = "${PN}"
|
|
USERADD_PARAM:${PN} = "--system --home-dir /var/lib/redis -g redis --shell /bin/false redis"
|
|
GROUPADD_PARAM:${PN} = "--system redis"
|
|
|
|
REDIS_ON_SYSTEMD = "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}"
|
|
|
|
do_compile:prepend() {
|
|
(cd deps && oe_runmake hiredis lua linenoise)
|
|
}
|
|
|
|
do_install() {
|
|
export PREFIX=${D}/${prefix}
|
|
oe_runmake install
|
|
install -d ${D}/${sysconfdir}/redis
|
|
install -m 0644 ${WORKDIR}/redis.conf ${D}/${sysconfdir}/redis/redis.conf
|
|
install -d ${D}/${sysconfdir}/init.d
|
|
install -m 0755 ${WORKDIR}/init-redis-server ${D}/${sysconfdir}/init.d/redis-server
|
|
install -d ${D}/var/lib/redis/
|
|
chown redis.redis ${D}/var/lib/redis/
|
|
|
|
install -d ${D}${systemd_system_unitdir}
|
|
install -m 0644 ${WORKDIR}/redis.service ${D}${systemd_system_unitdir}
|
|
sed -i 's!/usr/sbin/!${sbindir}/!g' ${D}${systemd_system_unitdir}/redis.service
|
|
|
|
if [ "${REDIS_ON_SYSTEMD}" = true ]; then
|
|
sed -i 's!daemonize yes!# daemonize yes!' ${D}/${sysconfdir}/redis/redis.conf
|
|
fi
|
|
}
|
|
|
|
CONFFILES:${PN} = "${sysconfdir}/redis/redis.conf"
|
|
|
|
INITSCRIPT_NAME = "redis-server"
|
|
INITSCRIPT_PARAMS = "defaults 87"
|
|
|
|
SYSTEMD_SERVICE:${PN} = "redis.service"
|