mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-09-16 12:12:16 +02:00
e18d8c9570
This helps in avoiding packaging errors seen with distros enabling multilib Fixes ERROR: grpc-1.24.3-r0 do_package: QA Issue: grpc: Files/directories were installed but not shipped in any package: /usr/lib/libgrpc++.so.1.24.3 ... /usr/lib/cmake /usr/lib/cmake/grpc /usr/lib/cmake/grpc/gRPCConfigVersion.cmake /usr/lib/cmake/grpc/gRPCConfig.cmake /usr/lib/cmake/grpc/gRPCTargets-noconfig.cmake /usr/lib/cmake/grpc/gRPCTargets.cmake Please set FILES such that these items are packaged. Alternatively if they are unneeded, avoid installing them or de lete them within do_install. Signed-off-by: Khem Raj <raj.khem@gmail.com>
56 lines
2.3 KiB
BlitzBasic
56 lines
2.3 KiB
BlitzBasic
DESCRIPTION = "A high performance, open source, general-purpose RPC framework. \
|
|
Provides gRPC libraries for multiple languages written on top of shared C core library \
|
|
(C++, Node.js, Python, Ruby, Objective-C, PHP, C#)"
|
|
HOMEPAGE = "https://github.com/grpc/grpc"
|
|
SECTION = "libs"
|
|
LICENSE = "Apache-2"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57"
|
|
|
|
DEPENDS = "gflags c-ares protobuf protobuf-native protobuf-c protobuf-c-native openssl libnsl2"
|
|
DEPENDS_append_class-target = " googletest grpc-native "
|
|
DEPENDS_append_class-nativesdk = " grpc-native "
|
|
|
|
S = "${WORKDIR}/git"
|
|
SRCREV_grpc = "2de2e8dd8921e1f7d043e01faf7fe8a291fbb072"
|
|
SRCREV_upb = "9effcbcb27f0a665f9f345030188c0b291e32482"
|
|
BRANCH = "v1.24.x"
|
|
SRC_URI = "git://github.com/grpc/grpc.git;protocol=https;name=grpc;branch=${BRANCH} \
|
|
git://github.com/protocolbuffers/upb;name=upb;destsuffix=git/third_party/upb \
|
|
file://0001-CMakeLists.txt-Fix-libraries-installation-for-Linux.patch \
|
|
"
|
|
SRC_URI_append_class-target = " file://0001-CMakeLists.txt-Fix-grpc_cpp_plugin-path-during-cross.patch \
|
|
"
|
|
SRC_URI_append_class-nativesdk = " file://0001-CMakeLists.txt-Fix-grpc_cpp_plugin-path-during-cross.patch"
|
|
|
|
# Fixes build with older compilers 4.8 especially on ubuntu 14.04
|
|
CXXFLAGS_append_class-native = " -Wl,--no-as-needed"
|
|
|
|
inherit cmake pkgconfig
|
|
|
|
EXTRA_OECMAKE = " \
|
|
-DgRPC_CARES_PROVIDER=package \
|
|
-DgRPC_ZLIB_PROVIDER=package \
|
|
-DgRPC_SSL_PROVIDER=package \
|
|
-DgRPC_PROTOBUF_PROVIDER=package \
|
|
-DgRPC_GFLAGS_PROVIDER=package \
|
|
-DgRPC_INSTALL=ON \
|
|
-DCMAKE_CROSSCOMPILING=ON \
|
|
-DBUILD_SHARED_LIBS=ON \
|
|
-DgRPC_INSTALL_LIBDIR=${baselib} \
|
|
-DgRPC_INSTALL_CMAKEDIR=${baselib}/cmake/${BPN} \
|
|
"
|
|
|
|
do_configure_prepend_mipsarch() {
|
|
sed -i -e "s/set(_gRPC_ALLTARGETS_LIBRARIES \${CMAKE_DL_LIBS} rt m pthread)/set(_gRPC_ALLTARGETS_LIBRARIES \${CMAKE_DL_LIBS} atomic rt m pthread)/g" ${S}/CMakeLists.txt
|
|
}
|
|
|
|
do_configure_prepend_toolchain-clang_x86() {
|
|
sed -i -e "s/set(_gRPC_ALLTARGETS_LIBRARIES \${CMAKE_DL_LIBS} rt m pthread)/set(_gRPC_ALLTARGETS_LIBRARIES \${CMAKE_DL_LIBS} atomic rt m pthread)/g" ${S}/CMakeLists.txt
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
SYSROOT_DIRS_BLACKLIST_append_class-target = "${baselib}/cmake/grpc"
|
|
|
|
FILES_${PN}-dev += "${bindir}"
|