mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-09-16 12:12:16 +02:00
11e6038282
Backported patch is included see '<-' in annnouncement: News ==== * Handle mode set race conditions more gracefully [Jonas; !1007] * Fix fallback to GLES2 [Adam; #635] <- * Fix interoperation with wl_data_device_manager v1 [Carlos; #965] * Fix visual glitches with offscreen effects applied [Georges; !992] * Favor text over images in clipboard manager [Carlos; #919] * Fixes crashes [Jonas, Carlos; !961, !869] * Plugged memory leaks [Sebastian, Adam; !1002, !1011] * Misc. bug fixes [Carlos, Robert, Olivier; !1005, #878, !1031, !1034, !1040] Signed-off-by: Andreas Müller <schnitzeltony@gmail.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
96 lines
3.2 KiB
BlitzBasic
96 lines
3.2 KiB
BlitzBasic
SUMMARY = "Window and compositing manager based on Clutter"
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
|
|
DEPENDS = " \
|
|
xserver-xorg-cvt-native \
|
|
virtual/libx11 \
|
|
gtk+3 \
|
|
gdk-pixbuf \
|
|
cairo \
|
|
pango \
|
|
gsettings-desktop-schemas \
|
|
json-glib \
|
|
gnome-desktop3 \
|
|
gnome-settings-daemon \
|
|
libxtst \
|
|
libxkbfile \
|
|
xinerama \
|
|
"
|
|
|
|
GNOMEBASEBUILDCLASS = "meson"
|
|
|
|
inherit gnomebase gsettings gobject-introspection gettext upstream-version-is-even features_check
|
|
|
|
SRC_URI[archive.md5sum] = "de19a6de98a2250dd7efdfca14359e39"
|
|
SRC_URI[archive.sha256sum] = "0134513515f605dd0858154d0b54d2e23c5779d52590533e266d407251e20ba2"
|
|
|
|
# x11 is still manadatory - see meson.build
|
|
REQUIRED_DISTRO_FEATURES = "x11"
|
|
|
|
# systemd can be replaced by libelogind (not available atow - make systemd
|
|
# mandatory distro feature)
|
|
LOGIND ?= "systemd"
|
|
REQUIRED_DISTRO_FEATURES += "systemd"
|
|
|
|
# profiler requires sysprof 3.34 which is not willing to build atow
|
|
PACKAGECONFIG ??= " \
|
|
native-backend \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'opengl x11', 'opengl glx', '', d)} \
|
|
sm \
|
|
startup-notification \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'opengl wayland', 'wayland', '', d)} \
|
|
"
|
|
|
|
EXTRA_OEMESON += " \
|
|
-Dxwayland_path=${bindir}/Xwayland \
|
|
"
|
|
|
|
# combi-config - see meson_options.txt for more details
|
|
PACKAGECONFIG[native-backend] = "-Dnative_backend=true -Dudev=true, -Dnative_backend=false -Dudev=false, libdrm virtual/libgbm libinput ${LOGIND} virtual/egl virtual/libgles2 udev"
|
|
PACKAGECONFIG[opengl] = "-Dopengl=true, -Dopengl=true, virtual/libgl"
|
|
PACKAGECONFIG[glx] = "-Dglx=true, -Dglx=false"
|
|
PACKAGECONFIG[libwacom] = "-Dlibwacom=true, -Dlibwacom=false, libwacom"
|
|
PACKAGECONFIG[remote-desktop] = "-Dremote_desktop=true, -Dremote_desktop=false, pipewire"
|
|
PACKAGECONFIG[sm] = "-Dsm=true, -Dsm=false, libsm"
|
|
PACKAGECONFIG[profiler] = "-Dprofiler=true,-Dprofiler=false,sysprof"
|
|
PACKAGECONFIG[startup-notification] = "-Dstartup_notification=true, -Dstartup_notification=false, startup-notification, startup-notification"
|
|
PACKAGECONFIG[wayland] = "-Dwayland=true,-Dwayland=false,wayland wayland-native, xserver-xorg-xwayland"
|
|
PACKAGECONFIG[wayland-eglstream] = "-Dwayland_eglstream=true,-Dwayland_eglstream=false"
|
|
|
|
# yes they changed from mutter-4 -> mutter-5 recently so be perpared
|
|
MUTTER_API_NAME = "mutter-5"
|
|
|
|
do_install_append() {
|
|
# Add gir links in standard paths. That makes dependents life much easier
|
|
# to find them
|
|
install -d ${D}${datadir}/gir-1.0
|
|
for gir_full in `find ${D}${libdir}/${MUTTER_API_NAME} -name '*.gir'`; do
|
|
gir=`basename "$gir_full"`
|
|
ln -sr "${D}${libdir}/${MUTTER_API_NAME}/$gir" "${D}${datadir}/gir-1.0/$gir"
|
|
done
|
|
}
|
|
|
|
PACKAGES =+ "${PN}-tests"
|
|
|
|
FILES_${PN} += " \
|
|
${datadir}/gnome-control-center \
|
|
${libdir}/${MUTTER_API_NAME}/lib*${SOLIBS} \
|
|
${libdir}/${MUTTER_API_NAME}/*.typelib \
|
|
${libdir}/${MUTTER_API_NAME}/plugins \
|
|
"
|
|
|
|
FILES_${PN}-tests += " \
|
|
${datadir}/installed-tests \
|
|
${datadir}/${MUTTER_API_NAME}/tests \
|
|
${libexecdir}/installed-tests/${MUTTER_API_NAME} \
|
|
"
|
|
|
|
FILES_${PN}-dev += " \
|
|
${libdir}/${MUTTER_API_NAME}/*.gir \
|
|
${libdir}/${MUTTER_API_NAME}/lib*.so \
|
|
"
|
|
|
|
RDEPENDS_${PN} += "zenity"
|
|
|