mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-09-17 12:41:58 +02:00
41f3f8165b
Changing the behavior of a recipe by including a layer is not allowed
by the yocto-check-layer script.
INFO: ======================================================================
INFO: FAIL: test_signatures (common.CommonCheckLayer)
INFO: ----------------------------------------------------------------------
INFO: Traceback (most recent call last):
File "/poky/scripts/lib/checklayer/cases/common.py", line 53, in test_signatures
self.fail('Adding layer %s changed signatures.\n%s' % (self.tc.layer['name'], msg))
AssertionError: Adding layer meta-xfce changed signatures.
19 signatures changed, initial differences (first hash before, second after):
vim:do_install: 7f165dbd724ca0127dfb653ef0ecd8e7fb882713adedfd0e14f59d7f54cb645e -> 6e4a49063534d67f70186bf8bdb313184f42426e2c42b12b127638b586c7ffe8
bitbake-diffsigs --task vim do_install --signature 7f165dbd724ca0127dfb653ef0ecd8e7fb882713adedfd0e14f59d7f54cb645e
fix by move the logic into recipe vim
Signed-off-by: Mark Hatle <mark.hatle@windriver.com>
Signed-off-by: Changqing Li <changqing.li@windriver.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
130 lines
4.4 KiB
BlitzBasic
130 lines
4.4 KiB
BlitzBasic
SUMMARY = "Vi IMproved - enhanced vi editor"
|
|
SECTION = "console/utils"
|
|
|
|
PROVIDES = "xxd"
|
|
DEPENDS = "ncurses gettext-native"
|
|
# vimdiff doesn't like busybox diff
|
|
RSUGGESTS_${PN} = "diffutils"
|
|
LICENSE = "vim"
|
|
LIC_FILES_CHKSUM = "file://../runtime/doc/uganda.txt;endline=287;md5=f1f82b42360005c70b8c19b0ef493f72"
|
|
|
|
SRC_URI = "git://github.com/vim/vim.git \
|
|
file://disable_acl_header_check.patch;patchdir=.. \
|
|
file://vim-add-knob-whether-elf.h-are-checked.patch;patchdir=.. \
|
|
file://0001-src-Makefile-improve-reproducibility.patch;patchdir=.. \
|
|
"
|
|
SRCREV = "f1c118be93184e8e57e3e80b1b3383f464ed649e"
|
|
|
|
S = "${WORKDIR}/git/src"
|
|
|
|
VIMDIR = "vim${@d.getVar('PV').split('.')[0]}${@d.getVar('PV').split('.')[1]}"
|
|
|
|
inherit autotools-brokensep update-alternatives
|
|
|
|
CLEANBROKEN = "1"
|
|
|
|
# vim configure.in contains functions which got 'dropped' by autotools.bbclass
|
|
do_configure () {
|
|
rm -f auto/*
|
|
touch auto/config.mk
|
|
aclocal
|
|
autoconf
|
|
oe_runconf
|
|
touch auto/configure
|
|
touch auto/config.mk auto/config.h
|
|
}
|
|
|
|
#Available PACKAGECONFIG options are gtkgui, acl, x11, tiny
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG += " \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'acl selinux', d)} \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11 gtkgui', '', d)} \
|
|
"
|
|
PACKAGECONFIG_class-native = ""
|
|
|
|
PACKAGECONFIG[gtkgui] = "--enable-gui=gtk2,--enable-gui=no,gtk+,"
|
|
PACKAGECONFIG[acl] = "--enable-acl,--disable-acl,acl,"
|
|
PACKAGECONFIG[x11] = "--with-x,--without-x,xt,"
|
|
PACKAGECONFIG[tiny] = "--with-features=tiny,--with-features=big,,"
|
|
PACKAGECONFIG[selinux] = "--enable-selinux,--disable-selinux,libselinux,"
|
|
PACKAGECONFIG[elfutils] = "--enable-elf-check,,elfutils,"
|
|
|
|
EXTRA_OECONF = " \
|
|
--disable-gpm \
|
|
--disable-gtktest \
|
|
--disable-xim \
|
|
--disable-netbeans \
|
|
--with-tlib=ncurses \
|
|
ac_cv_small_wchar_t=no \
|
|
vim_cv_getcwd_broken=no \
|
|
vim_cv_memmove_handles_overlap=yes \
|
|
vim_cv_stat_ignores_slash=no \
|
|
vim_cv_terminfo=yes \
|
|
vim_cv_tgetent=non-zero \
|
|
vim_cv_toupper_broken=no \
|
|
vim_cv_tty_group=world \
|
|
STRIP=/bin/true \
|
|
"
|
|
|
|
do_install() {
|
|
autotools_do_install
|
|
|
|
# Work around file-rdeps picking up csh, awk, perl or python as a dep
|
|
chmod -x ${D}${datadir}/${BPN}/${VIMDIR}/tools/vim132
|
|
chmod -x ${D}${datadir}/${BPN}/${VIMDIR}/tools/mve.awk
|
|
chmod -x ${D}${datadir}/${BPN}/${VIMDIR}/tools/*.pl
|
|
chmod -x ${D}${datadir}/${BPN}/${VIMDIR}/tools/*.py
|
|
|
|
# Install example vimrc from runtime files
|
|
install -m 0644 ../runtime/vimrc_example.vim ${D}/${datadir}/${BPN}/vimrc
|
|
|
|
# we use --with-features=big as default
|
|
mv ${D}${bindir}/${BPN} ${D}${bindir}/${BPN}.${BPN}
|
|
|
|
if ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'true', 'false', d)}; then
|
|
# The mouse being autoenabled is just annoying in xfce4-terminal (mouse
|
|
# drag make vim go into visual mode and there is no right click menu),
|
|
# delete the block.
|
|
sed -i '/the mouse works just fine/,+4d' ${D}/${datadir}/${BPN}/vimrc
|
|
fi
|
|
}
|
|
|
|
PARALLEL_MAKEINST = ""
|
|
|
|
PACKAGES =+ "${PN}-common ${PN}-syntax ${PN}-help ${PN}-tutor ${PN}-vimrc ${PN}-tools"
|
|
FILES_${PN}-syntax = "${datadir}/${BPN}/${VIMDIR}/syntax"
|
|
FILES_${PN}-help = "${datadir}/${BPN}/${VIMDIR}/doc"
|
|
FILES_${PN}-tutor = "${datadir}/${BPN}/${VIMDIR}/tutor ${bindir}/${BPN}tutor"
|
|
FILES_${PN}-vimrc = "${datadir}/${BPN}/vimrc"
|
|
FILES_${PN}-data = "${datadir}/${BPN}"
|
|
FILES_${PN}-tools = "${datadir}/${BPN}/${VIMDIR}/tools"
|
|
FILES_${PN}-common = " \
|
|
${datadir}/${BPN}/${VIMDIR}/*.vim \
|
|
${datadir}/${BPN}/${VIMDIR}/autoload \
|
|
${datadir}/${BPN}/${VIMDIR}/colors \
|
|
${datadir}/${BPN}/${VIMDIR}/compiler \
|
|
${datadir}/${BPN}/${VIMDIR}/ftplugin \
|
|
${datadir}/${BPN}/${VIMDIR}/indent \
|
|
${datadir}/${BPN}/${VIMDIR}/keymap \
|
|
${datadir}/${BPN}/${VIMDIR}/lang \
|
|
${datadir}/${BPN}/${VIMDIR}/macros \
|
|
${datadir}/${BPN}/${VIMDIR}/plugin \
|
|
${datadir}/${BPN}/${VIMDIR}/print \
|
|
${datadir}/${BPN}/${VIMDIR}/spell \
|
|
${datadir}/icons \
|
|
"
|
|
|
|
RDEPENDS_${BPN} = "ncurses-terminfo-base"
|
|
# Recommend that runtime data is installed along with vim
|
|
RRECOMMENDS_${BPN} = "${PN}-syntax ${PN}-help ${PN}-tutor ${PN}-vimrc ${PN}-common"
|
|
|
|
ALTERNATIVE_${PN} = "vi vim xxd"
|
|
ALTERNATIVE_PRIORITY = "100"
|
|
ALTERNATIVE_TARGET = "${bindir}/${BPN}.${BPN}"
|
|
ALTERNATIVE_LINK_NAME[vi] = "${base_bindir}/vi"
|
|
ALTERNATIVE_LINK_NAME[vim] = "${bindir}/vim"
|
|
ALTERNATIVE_TARGET[xxd] = "${bindir}/xxd"
|
|
ALTERNATIVE_LINK_NAME[xxd] = "${bindir}/xxd"
|
|
|
|
BBCLASSEXTEND = "native"
|