mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-09-16 12:12:16 +02:00
9499612fa2
Changelog: ============= * Add support for "allow-compression" parameter. * Fix a regression in preserving the "tls-auth" settings. * Add support for "tls-min" and "tls-cipher" parameters. * Include the new gnome-control-center name in the AppData file. * Drop libnm-glib support, nobody is likely using it anymore. * Fix importing profiles with a PKCS#12 CA. * Make sure the plugin object links with glib. * Dropped dependency on intltool. * Updated Basque, Brazilian Portuguese, Chinese (China), Croatian, Czech, Danish, Dutch, Georgian, Indonesian, Polish, Serbian, Spanish, Swedish, Turkish and Ukrainian translations. Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
53 lines
1.6 KiB
BlitzBasic
53 lines
1.6 KiB
BlitzBasic
SUMMARY = "NetworkManager-openvpn-plugin"
|
|
SECTION = "net/misc"
|
|
|
|
LICENSE = "GPL-2.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=100d5a599bead70ddcd70dcd73f2e29c"
|
|
|
|
DEPENDS = "dbus dbus-glib networkmanager openvpn intltool-native glib-2.0-native"
|
|
|
|
inherit gnomebase useradd gettext systemd
|
|
|
|
SRC_URI = "${GNOME_MIRROR}/NetworkManager-openvpn/${@gnome_verdir("${PV}")}/NetworkManager-openvpn-${PV}.tar.xz"
|
|
|
|
SRC_URI[sha256sum] = "5745d4107f3398a97afbb93f69239b510c9e45eb7fb62d60d9ed0a7297f4d101"
|
|
|
|
S = "${WORKDIR}/NetworkManager-openvpn-${PV}"
|
|
|
|
# meta-gnome in layers is required using gnome:
|
|
PACKAGECONFIG[gnome] = "--with-gnome,--without-gnome,gtk+3 libnma libsecret"
|
|
|
|
do_configure:append() {
|
|
# network-manager-openvpn.metainfo.xml is created in source folder but
|
|
# compile expects it in build folder. As long as nobody comes up with a
|
|
# better solution just support build:
|
|
if [ -e ${S}/appdata/network-manager-openvpn.metainfo.xml ]; then
|
|
mkdir -p ${B}/appdata
|
|
cp -f ${S}/appdata/network-manager-openvpn.metainfo.xml ${B}/appdata/
|
|
fi
|
|
}
|
|
|
|
do_install:append () {
|
|
rm -rf ${D}${libdir}/NetworkManager/*.la
|
|
}
|
|
|
|
# Create user and group nm-openvpn that are needed since version 1.0.6
|
|
USERADD_PACKAGES = "${PN}"
|
|
USERADD_PARAM:${PN} = "--system nm-openvpn"
|
|
|
|
FILES:${PN} += " \
|
|
${datadir}/dbus-1 \
|
|
${datadir}/metainfo \
|
|
${libdir}/NetworkManager/*.so \
|
|
${nonarch_libdir}/NetworkManager/VPN/nm-openvpn-service.name \
|
|
"
|
|
|
|
FILES:${PN}-staticdev += " \
|
|
${libdir}/NetworkManager/*.a \
|
|
"
|
|
|
|
RDEPENDS:${PN} = " \
|
|
networkmanager \
|
|
openvpn \
|
|
"
|