mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-09-16 12:12:16 +02:00
64ed8b631f
Commitc6e963f9e("lvm2: Add RDEPEND on lvm2 to lvm2-udevrules") added a package dependency due to lvm2-udevrules needs dmsetup, however dmsetup was moved to libdevmapper in commit269d009a81("lvm2: libdevicemapper package needs udev rules and dmsetup"), so this dependency should be only for libdevmapper instead of the full package. With the current implementation, a package that has a dependency with lvm2-udev rules will include also many unnecessary packages like lvm2, lvm2-scripts, etc. and their dependencies. Signed-off-by: Arturo Buzarra <arturo.buzarra@digi.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
63 lines
2.2 KiB
BlitzBasic
63 lines
2.2 KiB
BlitzBasic
require lvm2.inc
|
|
|
|
SRCREV = "913c28917e62577a2ef67152b2e5159237503dda"
|
|
|
|
SRC_URI += "file://0001-explicitly-do-not-install-libdm.patch \
|
|
file://0001-dev-hdc-open-failed-No-medium-found-will-print-out-i.patch \
|
|
"
|
|
|
|
DEPENDS += "autoconf-archive-native"
|
|
|
|
inherit multilib_script
|
|
|
|
MULTILIB_SCRIPTS = "${PN}:${sysconfdir}/lvm/lvm.conf"
|
|
|
|
CACHED_CONFIGUREVARS += "MODPROBE_CMD=${base_sbindir}/modprobe"
|
|
|
|
do_install_append() {
|
|
# Install machine specific configuration file
|
|
install -d ${D}${sysconfdir}/lvm
|
|
install -m 0644 ${WORKDIR}/lvm.conf ${D}${sysconfdir}/lvm/lvm.conf
|
|
sed -i -e 's:@libdir@:${libdir}:g' ${D}${sysconfdir}/lvm/lvm.conf
|
|
if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
|
|
oe_runmake 'DESTDIR=${D}' install install_systemd_units
|
|
sed -i -e 's:/usr/bin/true:${base_bindir}/true:g' ${D}${systemd_system_unitdir}/blk-availability.service
|
|
else
|
|
oe_runmake 'DESTDIR=${D}' install install_initscripts
|
|
mv ${D}${sysconfdir}/rc.d/init.d ${D}${sysconfdir}/init.d
|
|
rm -rf ${D}${sysconfdir}/rc.d
|
|
fi
|
|
}
|
|
|
|
PACKAGE_BEFORE_PN = "${PN}-scripts ${PN}-udevrules"
|
|
|
|
SYSTEMD_PACKAGES = "${PN}"
|
|
SYSTEMD_SERVICE_${PN} = "${@bb.utils.contains('PACKAGECONFIG', 'dmeventd', 'lvm2-monitor.service dm-event.socket dm-event.service', '', d)} \
|
|
blk-availability.service lvm2-pvscan@.service"
|
|
SYSTEMD_AUTO_ENABLE = "disable"
|
|
|
|
TARGET_CC_ARCH += "${LDFLAGS}"
|
|
|
|
EXTRA_OECONF_append_class-nativesdk = " --with-confdir=${sysconfdir}"
|
|
|
|
FILES_${PN} += "${libdir}/device-mapper/*.so"
|
|
FILES_${PN}-scripts = " \
|
|
${sbindir}/blkdeactivate \
|
|
${sbindir}/fsadm \
|
|
${sbindir}/lvmconf \
|
|
${sbindir}/lvmdump \
|
|
"
|
|
# Specified explicitly for the udev rules, just in case that it does not get picked
|
|
# up automatically:
|
|
FILES_${PN}-udevrules = "${nonarch_base_libdir}/udev/rules.d"
|
|
RDEPENDS_${PN}-udevrules = "libdevmapper"
|
|
RDEPENDS_${PN}_append_class-target = " libdevmapper"
|
|
RDEPENDS_${PN}_append_class-nativesdk = " libdevmapper"
|
|
|
|
RDEPENDS_${PN}-scripts = "${PN} (= ${EXTENDPKGV}) bash"
|
|
RRECOMMENDS_${PN}_class-target = "${PN}-scripts (= ${EXTENDPKGV})"
|
|
|
|
CONFFILES_${PN} += "${sysconfdir}/lvm/lvm.conf"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|