mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-09-18 13:11:57 +02:00
dd3ce95fb0
There's conflict of config.h between dovecot and lib32-dovecot. The differences of config-64.h and config-32.h are as follows: @@ -774,7 +774,7 @@ #define MODULE_SUFFIX ".so" /* Maximum value of off_t */ -#define OFF_T_MAX LONG_MAX +#define OFF_T_MAX LLONG_MAX /* Name of package */ #define PACKAGE "dovecot" @@ -834,7 +834,7 @@ #define PRIdTIME_T "ld" /* printf() format for uoff_t */ -#define PRIuUOFF_T "lu" +#define PRIuUOFF_T "llu" /* printf() fmt for hex time_t */ #define PRIxTIME_T "lx" @@ -846,19 +846,19 @@ #define SIZEOF_INT 4 /* The size of `long', as computed by sizeof. */ -#define SIZEOF_LONG 8 +#define SIZEOF_LONG 4 /* The size of `long long', as computed by sizeof. */ #define SIZEOF_LONG_LONG 8 /* The size of `void *', as computed by sizeof. */ -#define SIZEOF_VOID_P 8 +#define SIZEOF_VOID_P 4 /* Build SQL drivers as plugins */ /* #undef SQL_DRIVER_PLUGINS */ /* Maximum value of ssize_t */ -#define SSIZE_T_MAX LONG_MAX +#define SSIZE_T_MAX INT_MAX /* C99 static array */ #define STATIC_ARRAY static @@ -887,13 +887,13 @@ /* #undef UOFF_T_INT */ /* Define if off_t is long */ -#define UOFF_T_LONG /**/ +/* #undef UOFF_T_LONG */ /* Define if off_t is long long */ -/* #undef UOFF_T_LONG_LONG */ +#define UOFF_T_LONG_LONG /**/ /* Maximum value of uoff_t */ -#define UOFF_T_MAX ULONG_MAX +#define UOFF_T_MAX ULLONG_MAX /* Build with checkpassword userdb support */ #define USERDB_CHECKPASSWORD /**/ @@ -935,7 +935,7 @@ #endif /* Number of bits in a file offset, on hosts where this is settable. */ -/* #undef _FILE_OFFSET_BITS */ +#define _FILE_OFFSET_BITS 64 /* Define for large files, on AIX-style hosts. */ /* #undef _LARGE_FILES */ Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
76 lines
3.4 KiB
BlitzBasic
76 lines
3.4 KiB
BlitzBasic
SUMMARY = "Dovecot is an open source IMAP and POP3 email server"
|
|
HOMEPAGE = "https://www.dovecot.org/"
|
|
DESCRIPTION = "Dovecot is an open source IMAP and POP3 email server for Linux/UNIX-like systems, written with security primarily in mind. Dovecot is an excellent choice for both small and large installations. It's fast, simple to set up, requires no special administration and it uses very little memory."
|
|
SECTION = "mail"
|
|
LICENSE = "LGPL-2.1-only & MIT"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=2956560272e5b31d9d64f03111732048"
|
|
|
|
SRC_URI = "http://dovecot.org/releases/2.3/dovecot-${PV}.tar.gz \
|
|
file://0001-configure.ac-convert-AC_TRY_RUN-to-AC_TRY_LINK-state.patch \
|
|
file://dovecot.service \
|
|
file://dovecot.socket \
|
|
file://0001-not-check-pandoc.patch \
|
|
file://0001-m4-Check-for-libunwind-instead-of-libunwind-generic.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "caa832eb968148abdf35ee9d0f534b779fa732c0ce4a913d9ab8c3469b218552"
|
|
|
|
DEPENDS = "openssl xz zlib bzip2 libcap icu libtirpc bison-native"
|
|
CFLAGS += "-I${STAGING_INCDIR}/tirpc"
|
|
LDFLAGS += "-ltirpc"
|
|
|
|
inherit autotools pkgconfig systemd useradd gettext multilib_header
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'ldap pam systemd', d)}"
|
|
|
|
PACKAGECONFIG[pam] = "--with-pam,--without-pam,libpam,"
|
|
PACKAGECONFIG[systemd] = "--with-systemd,--without-systemd,systemd,"
|
|
PACKAGECONFIG[ldap] = "--with-ldap=plugin,--without-ldap,openldap,"
|
|
PACKAGECONFIG[lz4] = "--with-lz4,--without-lz4,lz4,"
|
|
|
|
# From native build in armv7a-hf/eglibc
|
|
CACHED_CONFIGUREVARS += "i_cv_signed_size_t=no \
|
|
i_cv_gmtime_max_time_t=32 \
|
|
i_cv_signed_time_t=yes \
|
|
i_cv_mmap_plays_with_write=yes \
|
|
i_cv_fd_passing=yes \
|
|
i_cv_c99_vsnprintf=yes \
|
|
lib_cv___va_copy=yes \
|
|
lib_cv_va_copy=yes \
|
|
lib_cv_va_val_copy=yes \
|
|
"
|
|
|
|
# hardcode epoll() to avoid running unsafe tests
|
|
# BSD needs kqueue and uclibc poll()
|
|
EXTRA_OECONF = " --with-ioloop=epoll"
|
|
|
|
SYSTEMD_PACKAGES = "${PN}"
|
|
SYSTEMD_SERVICE:${PN} = "dovecot.service dovecot.socket"
|
|
SYSTEMD_AUTO_ENABLE = "disable"
|
|
|
|
do_install:append () {
|
|
rm -rf ${D}${libdir}/dovecot/dovecot-config
|
|
install -d 755 ${D}/etc/dovecot
|
|
touch 644 ${D}/etc/dovecot/dovecot.conf
|
|
if [ "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)}" ]; then
|
|
install -m 0644 ${WORKDIR}/dovecot.service ${D}${systemd_unitdir}/system
|
|
sed -i -e 's#@SYSCONFDIR@#${sysconfdir}#g' ${D}${systemd_unitdir}/system/dovecot.service
|
|
sed -i -e 's#@SBINDIR@#${sbindir}#g' ${D}${systemd_unitdir}/system/dovecot.service
|
|
fi
|
|
oe_multilib_header dovecot/config.h
|
|
}
|
|
|
|
USERADD_PACKAGES = "${PN}"
|
|
USERADD_PARAM:${PN} = "-r -d ${libexecdir} -M -s ${base_sbindir}/nologin -g dovecot dovecot; \
|
|
-r -d ${libexecdir} -M -s ${base_sbindir}/nologin -g dovenull dovenull"
|
|
GROUPADD_PARAM:${PN} = "-f -r dovecot;-f -r dovenull"
|
|
|
|
FILES:${PN} += "${libdir}/dovecot/*plugin.so \
|
|
${libdir}/dovecot/libfs_compress.so \
|
|
${libdir}/dovecot/libssl_iostream_openssl.so"
|
|
FILES:${PN}-staticdev += "${libdir}/dovecot/*/*.a"
|
|
FILES:${PN}-dev += "${libdir}/dovecot/libdovecot*.so"
|
|
FILES:${PN}-dbg += "${libdir}/dovecot/*/.debug"
|
|
|
|
# CVE-2016-4983 affects only postinstall script on specific distribution
|
|
CVE_CHECK_IGNORE += "CVE-2016-4983"
|