mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-09-16 12:12:16 +02:00
b8a5f0740b
Version 2.18.2, 2021-10-25 Avoid using short exponents when encrypting in ElGamal, as some PGP implementations generate keys with parameters that are weak when short exponents are used (GH #2794) Fix a low risk OAEP decryption side channel (GH #2797) Work around a miscompilation of SHA-3 caused by a bug in Clang 12 and XCode 13. (GH #2826) Remove support in OpenSSL provider for algorithms which are disabled by default in OpenSSL 3.0 (GH #2823, #2814) Add CI based on GitHub actions to replace Travis CI (GH #2632) Fix the online OCSP test, as the certificate involved had expired. (GH #2799) Fix some test failures induced by the expiration of the trust root "DST Root CA X3" (GH #2820) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
53 lines
1.3 KiB
BlitzBasic
53 lines
1.3 KiB
BlitzBasic
SUMMARY = "Crypto and TLS for C++11"
|
|
HOMEPAGE = "https://botan.randombit.net"
|
|
LICENSE = "BSD-2-Clause"
|
|
LIC_FILES_CHKSUM = "file://license.txt;md5=a02e03c8fa2c5e7b9b3fcc1b9811fd3b"
|
|
SECTION = "libs"
|
|
|
|
SRC_URI = "https://botan.randombit.net/releases/Botan-${PV}.tar.xz"
|
|
SRC_URI[sha256sum] = "541a3b13f1b9d30f977c6c1ae4c7bfdfda763cda6e44de807369dce79f42307e"
|
|
|
|
S = "${WORKDIR}/Botan-${PV}"
|
|
|
|
inherit python3native siteinfo lib_package
|
|
|
|
CPU ?= "${TARGET_ARCH}"
|
|
CPU:x86 = "x86_32"
|
|
CPU:armv7a = "armv7"
|
|
CPU:armv7ve = "armv7"
|
|
|
|
do_configure() {
|
|
python3 ${S}/configure.py \
|
|
--prefix="${D}${exec_prefix}" \
|
|
--libdir="${D}${libdir}" \
|
|
--cpu="${CPU}" \
|
|
--cc-bin="${CXX}" \
|
|
--cxxflags="${CXXFLAGS}" \
|
|
--ldflags="${LDFLAGS}" \
|
|
--with-endian=${@oe.utils.conditional('SITEINFO_ENDIANNESS', 'le', 'little', 'big', d)} \
|
|
${@bb.utils.contains("TUNE_FEATURES","neon","","--disable-neon",d)} \
|
|
--with-sysroot-dir=${STAGING_DIR_HOST} \
|
|
--with-build-dir="${B}" \
|
|
--optimize-for-size \
|
|
--with-stack-protector \
|
|
--enable-shared-library \
|
|
--with-python-versions=3 \
|
|
${EXTRA_OECONF}
|
|
}
|
|
|
|
do_compile() {
|
|
oe_runmake
|
|
}
|
|
do_install() {
|
|
oe_runmake install
|
|
sed -i -e "s|${D}||g" ${D}${libdir}/pkgconfig/botan-2.pc
|
|
}
|
|
|
|
PACKAGES += "${PN}-python3"
|
|
|
|
FILES:${PN}-python3 = "${libdir}/python3"
|
|
|
|
RDEPENDS:${PN}-python3 += "python3"
|
|
|
|
COMPATIBLE_HOST:riscv32 = "null"
|