mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-09-16 20:21:58 +02:00
cc976ef344
Changelog: ========== tls-crypt-v2: bail out if the client key is too small Remove useless empty line from CR_RESPONSE message Allow running a default configuration with TLS libraries without BF-CBC Change command help to match man page and implementation Fix OpenVPN querying user/password if auth-token with user expires t_client: Allow to force FAIL on prerequisite fails t_client.sh: do not require fping6 Preparing release 2.5.8 msvc: add branch name and commit hash to version output Update the replay-window backtrack log message Do not skip ERROR:/SUCCESS: response from management interface Fix auth-token usage with management-def-auth Allow a few levels of recursion in virtual_output_callback() Ensure --auth-nocache is handled during renegotiation Purge auth-token as well while purging passwords Do not copy auth_token username to itself Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
78 lines
3.2 KiB
BlitzBasic
78 lines
3.2 KiB
BlitzBasic
SUMMARY = "A full-featured SSL VPN solution via tun device."
|
|
HOMEPAGE = "https://openvpn.net/"
|
|
SECTION = "net"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b76abd82c14ee01cc34c4ff5e3627b89"
|
|
DEPENDS = "lzo openssl iproute2 ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"
|
|
|
|
inherit autotools systemd update-rc.d pkgconfig
|
|
|
|
SRC_URI = "http://swupdate.openvpn.org/community/releases/${BP}.tar.gz \
|
|
file://0001-configure.ac-eliminate-build-path-from-openvpn-versi.patch \
|
|
file://openvpn \
|
|
"
|
|
|
|
UPSTREAM_CHECK_URI = "https://openvpn.net/community-downloads"
|
|
|
|
SRC_URI[sha256sum] = "a6f315b7231d44527e65901ff646f87d7f07862c87f33531daa109fb48c53db2"
|
|
|
|
# CVE-2020-7224 and CVE-2020-27569 are for Aviatrix OpenVPN client, not for openvpn.
|
|
CVE_CHECK_IGNORE += "CVE-2020-7224 CVE-2020-27569"
|
|
|
|
INITSCRIPT_PACKAGES = "${PN}"
|
|
INITSCRIPT_NAME:${PN} = "openvpn"
|
|
INITSCRIPT_PARAMS:${PN} = "start 10 2 3 4 5 . stop 70 0 1 6 ."
|
|
|
|
CFLAGS += "-fno-inline"
|
|
|
|
# I want openvpn to be able to read password from file (hrw)
|
|
EXTRA_OECONF += "--enable-iproute2"
|
|
EXTRA_OECONF += "${@bb.utils.contains('DISTRO_FEATURES', 'pam', '', '--disable-plugin-auth-pam', d)}"
|
|
|
|
# Explicitly specify IPROUTE to bypass the configure-time check for /sbin/ip on the host.
|
|
EXTRA_OECONF += "IPROUTE=${base_sbindir}/ip"
|
|
|
|
EXTRA_OECONF += "SYSTEMD_UNIT_DIR=${systemd_system_unitdir} \
|
|
TMPFILES_DIR=${nonarch_libdir}/tmpfiles.d \
|
|
"
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'selinux', d)} \
|
|
"
|
|
|
|
PACKAGECONFIG[systemd] = "--enable-systemd,--disable-systemd,systemd"
|
|
PACKAGECONFIG[selinux] = "--enable-selinux,--disable-selinux,libselinux"
|
|
|
|
do_install:append() {
|
|
install -d ${D}/${sysconfdir}/init.d
|
|
install -m 755 ${WORKDIR}/openvpn ${D}/${sysconfdir}/init.d
|
|
|
|
install -d ${D}/${sysconfdir}/openvpn
|
|
install -d ${D}/${sysconfdir}/openvpn/server
|
|
install -d ${D}/${sysconfdir}/openvpn/client
|
|
|
|
install -d ${D}/${sysconfdir}/openvpn/sample
|
|
install -m 644 ${S}/sample/sample-config-files/loopback-server ${D}${sysconfdir}/openvpn/sample/loopback-server.conf
|
|
install -m 644 ${S}/sample/sample-config-files/loopback-client ${D}${sysconfdir}/openvpn/sample/loopback-client.conf
|
|
install -dm 755 ${D}${sysconfdir}/openvpn/sample/sample-config-files
|
|
install -dm 755 ${D}${sysconfdir}/openvpn/sample/sample-keys
|
|
install -dm 755 ${D}${sysconfdir}/openvpn/sample/sample-scripts
|
|
install -m 644 ${S}/sample/sample-config-files/* ${D}${sysconfdir}/openvpn/sample/sample-config-files
|
|
install -m 644 ${S}/sample/sample-keys/* ${D}${sysconfdir}/openvpn/sample/sample-keys
|
|
install -m 644 ${S}/sample/sample-scripts/* ${D}${sysconfdir}/openvpn/sample/sample-scripts
|
|
|
|
install -d -m 710 ${D}/${localstatedir}/lib/openvpn
|
|
}
|
|
|
|
PACKAGES =+ " ${PN}-sample "
|
|
|
|
RRECOMMENDS:${PN} = "kernel-module-tun"
|
|
|
|
FILES:${PN}-dbg += "${libdir}/openvpn/plugins/.debug"
|
|
FILES:${PN} += "${systemd_system_unitdir}/openvpn-server@.service \
|
|
${systemd_system_unitdir}/openvpn-client@.service \
|
|
${nonarch_libdir}/tmpfiles.d \
|
|
"
|
|
FILES:${PN}-sample = "${sysconfdir}/openvpn/sample/ \
|
|
"
|