mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-09-18 13:11:57 +02:00
1463adf1fe
Changelog: ========== - simplify the change for sixelScrolling from patch #374 - add xterm+focus and report+da2, update report+version building blocks in terminfo, from post-ncurses 6.4 - drop the -title option from uxterm and koi8rxterm, because that interferes with deriving the default title from the -e option (Debian #1031837). Compensate for this by using the -class option to derive a default title. - improve description of readline 2003 mode in ctlseqs.ms - other improvements to status-line feature clear status line on DECCOLM ignore DECSASD if no previous DECSSDT allow DECSSDT 1 immediately after DECSSDT 2, i.e., without switching back to host mode. - adjust RequestResize to avoid shrinking screen when using DECCOLM while the status-line is active - disallow wrapping before the beginning of the screen, to the end of the screen, for cursor-back sequences (Redhat #2182357). - modify makefile to install the 16x16 xpm files - update test-package to reflect resolution of Debian #906901. - change default of showMissingGlyphs to True. - improve handling of double-sized characters when those happen to be missing from the bitmap font and/or are fullwidth. - pointer/overflow fixes - configure script improvements - fix a typo in the underline cursor thickness derivation Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
51 lines
1.7 KiB
BlitzBasic
51 lines
1.7 KiB
BlitzBasic
require recipes-graphics/xorg-app/xorg-app-common.inc
|
|
SUMMARY = "xterm is the standard terminal emulator for the X Window System"
|
|
DEPENDS = "libxaw xorgproto libxext libxau libxinerama libxpm ncurses desktop-file-utils-native"
|
|
|
|
LIC_FILES_CHKSUM = "file://xterm.h;beginline=3;endline=31;md5=9c96124b492c0c02356850c243aaeca2"
|
|
|
|
SRC_URI = "http://invisible-mirror.net/archives/${BPN}/${BP}.tgz \
|
|
file://0001-Add-configure-time-check-for-setsid.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "0c1dc1fa800fa64b5c58d16ddb905e700b27ca538a65be8c03b2ba5761106c38"
|
|
|
|
PACKAGECONFIG ?= ""
|
|
PACKAGECONFIG[xft] = "--enable-freetype,--disable-freetype,libxft fontconfig freetype-native"
|
|
|
|
# Let xterm install .desktop files
|
|
inherit mime-xdg
|
|
|
|
EXTRA_OECONF = " --x-includes=${STAGING_INCDIR} \
|
|
--x-libraries=${STAGING_LIBDIR} \
|
|
FREETYPE_CONFIG=${STAGING_BINDIR_CROSS}/freetype-config \
|
|
--disable-imake \
|
|
--disable-rpath-hack \
|
|
--disable-setuid \
|
|
--with-app-defaults=${datadir}/X11/app-defaults \
|
|
"
|
|
|
|
B = "${S}"
|
|
|
|
CFLAGS += "-D_GNU_SOURCE"
|
|
|
|
do_configure() {
|
|
gnu-configize --force
|
|
sed -e "s%/usr/contrib/X11R6%${STAGING_LIBDIR}%g" -i configure
|
|
oe_runconf
|
|
}
|
|
|
|
do_install:append() {
|
|
oe_runmake install-desktop DESTDIR="${D}" DESKTOP_FLAGS="--dir=${D}${DESKTOPDIR}"
|
|
}
|
|
|
|
RPROVIDES:${PN} = "virtual-x-terminal-emulator"
|
|
|
|
# busybox can supply resize too
|
|
inherit update-alternatives
|
|
|
|
ALTERNATIVE:${PN} = "resize x-terminal-emulator"
|
|
ALTERNATIVE_TARGET[x-terminal-emulator] = "${bindir}/xterm"
|
|
# rxvt-unicode defaults to priority 10. Let's be one point lower to let it override xterm.
|
|
ALTERNATIVE_PRIORITY[x-terminal-emulator] = "9"
|