mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-09-17 20:51:57 +02:00
ef0bb73cd4
This includes the following changes: ver 1.7: Fix issue with APs that send IGTK falsely in big endian. Fix issue with setting linkmode & operstate for open networks. Signed-off-by: Pierre-Jean Texier <pjtexier@koncepto.io> Signed-off-by: Khem Raj <raj.khem@gmail.com>
55 lines
1.6 KiB
BlitzBasic
55 lines
1.6 KiB
BlitzBasic
SUMMARY = "Wireless daemon for Linux"
|
|
HOMEPAGE = "https://iwd.wiki.kernel.org/"
|
|
LICENSE = "LGPL-2.1"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=fb504b67c50331fc78734fed90fb0e09"
|
|
|
|
DEPENDS = "ell"
|
|
|
|
SRC_URI = "git://git.kernel.org/pub/scm/network/wireless/iwd.git"
|
|
SRCREV = "ef6084dcb4fe2e00327bb9c7b113ece204042c22"
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools manpages pkgconfig python3native systemd
|
|
|
|
PACKAGECONFIG ??= " \
|
|
client \
|
|
monitor \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} \
|
|
"
|
|
PACKAGECONFIG[client] = "--enable-client,--disable-client,readline"
|
|
PACKAGECONFIG[monitor] = "--enable-monitor,--disable-monitor"
|
|
PACKAGECONFIG[manpages] = "--enable-manual-pages,--disable-manual-pages,python3-docutils-native"
|
|
PACKAGECONFIG[wired] = "--enable-wired,--disable-wired"
|
|
PACKAGECONFIG[ofono] = "--enable-ofono,--disable-ofono"
|
|
PACKAGECONFIG[systemd] = "--with-systemd-unitdir=${systemd_system_unitdir},--disable-systemd-service,systemd"
|
|
|
|
EXTRA_OECONF = "--enable-external-ell"
|
|
|
|
SYSTEMD_SERVICE_${PN} = " \
|
|
iwd.service \
|
|
${@bb.utils.contains('PACKAGECONFIG', 'wired', 'ead.service', '', d)} \
|
|
"
|
|
|
|
do_configure_prepend() {
|
|
install -d ${S}/build-aux
|
|
}
|
|
|
|
do_install_append() {
|
|
# If client and monitor are disabled, bindir is empty, causing a QA error
|
|
rmdir --ignore-fail-on-non-empty ${D}/${bindir}
|
|
}
|
|
|
|
FILES_${PN} += " \
|
|
${datadir}/dbus-1 \
|
|
${nonarch_libdir}/modules-load.d \
|
|
${systemd_unitdir}/network \
|
|
"
|
|
|
|
RDEPENDS_${PN} = "dbus"
|
|
|
|
RRECOMMENDS_${PN} = "\
|
|
kernel-module-pkcs7-message \
|
|
kernel-module-pkcs8-key-parser \
|
|
kernel-module-x509-key-parser \
|
|
"
|