mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-09-17 20:51:57 +02:00
5098155437
Since uftrace-0.9.4 was released, there has been some important bug fixes. It would be better to include such bug fix commits so this patch updates the commit hash to more stable one. The bug fix patches are as follows: [1]a0fbee404b[2]251ba74a72[3]19e6f0d4b3[4]d648bbffedSigned-off-by: Honggyu Kim <honggyu.kp@gmail.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
46 lines
1.1 KiB
BlitzBasic
46 lines
1.1 KiB
BlitzBasic
SUMMARY = "Trace and analyze execution of a program written in C/C++"
|
|
HOMEPAGE = "https://github.com/namhyung/uftrace"
|
|
BUGTRACKER = "https://github.com/namhyung/uftrace/issues"
|
|
SECTION = "devel"
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
|
|
DEPENDS = "elfutils"
|
|
DEPENDS_append_libc-musl = " argp-standalone"
|
|
|
|
inherit autotools
|
|
|
|
# v0.9.4
|
|
SRCREV = "d648bbffedef529220896283fb59e35531c13804"
|
|
SRC_URI = "git://github.com/namhyung/${BPN} \
|
|
"
|
|
S = "${WORKDIR}/git"
|
|
|
|
LDFLAGS_append_libc-musl = " -largp"
|
|
|
|
def set_target_arch(d):
|
|
import re
|
|
arch = d.getVar('TARGET_ARCH')
|
|
if re.match(r'i.86', arch, re.I):
|
|
return 'i386'
|
|
elif re.match('armeb', arch, re.I):
|
|
return 'arm'
|
|
else:
|
|
return arch
|
|
|
|
EXTRA_UFTRACE_OECONF = "ARCH=${@set_target_arch(d)} \
|
|
with_elfutils=/use/libelf/from/sysroot"
|
|
|
|
do_configure() {
|
|
${S}/configure ${EXTRA_UFTRACE_OECONF}
|
|
}
|
|
|
|
FILES_SOLIBSDEV = ""
|
|
FILES_${PN} += "${libdir}/*.so"
|
|
|
|
COMPATIBLE_HOST = "(i.86|x86_64|aarch64|arm)"
|
|
|
|
# uftrace supports armv6 and above
|
|
COMPATIBLE_HOST_armv4 = 'null'
|
|
COMPATIBLE_HOST_armv5 = 'null'
|