mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-09-18 13:11:57 +02:00
c971a10498
0001-netconfig-Use-s6_addr-instead-of-__in6_u.__u6_addr8.patch removed since it is included in 1.19 ver 1.19: Fix issue with handling OCV if offloading is supported. Fix issue with handling SA Query on channel switch event. Fix issue with starting FT-over-DS actions after roaming. Add support for OWE transition networks. Add support for extended key IDs. Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
56 lines
1.7 KiB
BlitzBasic
56 lines
1.7 KiB
BlitzBasic
SUMMARY = "Wireless daemon for Linux"
|
|
HOMEPAGE = "https://iwd.wiki.kernel.org/"
|
|
LICENSE = "LGPL-2.1"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=fb504b67c50331fc78734fed90fb0e09"
|
|
|
|
DEPENDS = "ell"
|
|
|
|
SRC_URI = "https://www.kernel.org/pub/linux/network/wireless/${BP}.tar.xz \
|
|
file://0001-build-Use-abs_top_srcdir-instead-of-abs_srcdir-for-e.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "dd65a8795f6127fb1b9e29f2092686b0590a0d3738c2b90c792ccd320deaf966"
|
|
|
|
inherit autotools manpages pkgconfig python3native systemd
|
|
|
|
PACKAGECONFIG ??= " \
|
|
client \
|
|
monitor \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} \
|
|
"
|
|
PACKAGECONFIG[client] = "--enable-client,--disable-client,readline"
|
|
PACKAGECONFIG[monitor] = "--enable-monitor,--disable-monitor"
|
|
PACKAGECONFIG[manpages] = "--enable-manual-pages,--disable-manual-pages,python3-docutils-native"
|
|
PACKAGECONFIG[wired] = "--enable-wired,--disable-wired"
|
|
PACKAGECONFIG[ofono] = "--enable-ofono,--disable-ofono"
|
|
PACKAGECONFIG[systemd] = "--with-systemd-unitdir=${systemd_system_unitdir},--disable-systemd-service,systemd"
|
|
|
|
EXTRA_OECONF = "--enable-external-ell"
|
|
|
|
SYSTEMD_SERVICE:${PN} = " \
|
|
iwd.service \
|
|
${@bb.utils.contains('PACKAGECONFIG', 'wired', 'ead.service', '', d)} \
|
|
"
|
|
|
|
do_configure:prepend() {
|
|
install -d ${S}/build-aux
|
|
}
|
|
|
|
do_install:append() {
|
|
# If client and monitor are disabled, bindir is empty, causing a QA error
|
|
rmdir --ignore-fail-on-non-empty ${D}/${bindir}
|
|
}
|
|
|
|
FILES:${PN} += " \
|
|
${datadir}/dbus-1 \
|
|
${nonarch_libdir}/modules-load.d \
|
|
${systemd_unitdir}/network \
|
|
"
|
|
|
|
RDEPENDS:${PN} = "dbus"
|
|
|
|
RRECOMMENDS:${PN} = "\
|
|
kernel-module-pkcs7-message \
|
|
kernel-module-pkcs8-key-parser \
|
|
kernel-module-x509-key-parser \
|
|
"
|