mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-09-16 12:12:16 +02:00
fefc98980a
Signed-off-by: Andre McCurdy <armccurdy@gmail.com> Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
62 lines
2.8 KiB
BlitzBasic
62 lines
2.8 KiB
BlitzBasic
SUMMARY = "Audio decoder for MPEG-1 Layer 1/2/3"
|
|
DESCRIPTION = "The core of mpg123 is an MPEG-1 Layer 1/2/3 decoding library, which can be used by other programs. \
|
|
mpg123 also comes with a command-line tool which can playback using ALSA, PulseAudio, OSS, and several other APIs, \
|
|
and also can write the decoded audio to WAV."
|
|
HOMEPAGE = "http://mpg123.de/"
|
|
BUGTRACKER = "http://sourceforge.net/p/mpg123/bugs/"
|
|
SECTION = "multimedia"
|
|
|
|
LICENSE = "LGPLv2.1"
|
|
LICENSE_FLAGS = "commercial"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=1e86753638d3cf2512528b99079bc4f3"
|
|
|
|
DEPENDS = "tslib audiofile"
|
|
|
|
SRC_URI = "${SOURCEFORGE_MIRROR}/mpg123/mpg123/${PV}/${BP}.tar.bz2"
|
|
|
|
SRC_URI[md5sum] = "13a9df5d4e7aa110e4ae27cf30128ce9"
|
|
SRC_URI[sha256sum] = "3ad197f77c9ffdf3601e1c3183ae0709ccb3c3de68309527ce9375fcfb15dcba"
|
|
|
|
inherit autotools pkgconfig
|
|
|
|
# The options should be mutually exclusive for configuration script.
|
|
# If both alsa and pulseaudio are specified (as in the default distro features)
|
|
# pulseaudio takes precedence.
|
|
PACKAGECONFIG_ALSA = "${@base_contains('DISTRO_FEATURES', 'alsa', 'alsa', '', d)}"
|
|
PACKAGECONFIG ??= "${@base_contains('DISTRO_FEATURES', 'pulseaudio', 'pulseaudio', '${PACKAGECONFIG_ALSA}', d)}"
|
|
|
|
PACKAGECONFIG[alsa] = "--with-default-audio=alsa,,alsa-lib"
|
|
PACKAGECONFIG[esd] = ",,esound"
|
|
PACKAGECONFIG[jack] = ",,jack"
|
|
PACKAGECONFIG[openal] = ",,openal-soft"
|
|
PACKAGECONFIG[portaudio] = ",,portaudio-v19"
|
|
PACKAGECONFIG[pulseaudio] = "--with-default-audio=pulse,,pulseaudio"
|
|
PACKAGECONFIG[sdl] = ",,libsdl"
|
|
|
|
# Following are possible sound output modules:
|
|
# alsa arts coreaudio dummy esd jack nas openal os2 oss portaudio pulse sdl sndio sun tinyalsa win32 win32_wasapi
|
|
AUDIOMODS += "${@base_contains('PACKAGECONFIG', 'alsa', 'alsa', '', d)}"
|
|
AUDIOMODS += "${@base_contains('PACKAGECONFIG', 'esd', 'esd', '', d)}"
|
|
AUDIOMODS += "${@base_contains('PACKAGECONFIG', 'jack', 'jack', '', d)}"
|
|
AUDIOMODS += "${@base_contains('PACKAGECONFIG', 'openal', 'openal', '', d)}"
|
|
AUDIOMODS += "${@base_contains('PACKAGECONFIG', 'portaudio', 'portaudio', '', d)}"
|
|
AUDIOMODS += "${@base_contains('PACKAGECONFIG', 'pulseaudio', 'pulse', '', d)}"
|
|
AUDIOMODS += "${@base_contains('PACKAGECONFIG', 'sdl', 'sdl', '', d)}"
|
|
|
|
EXTRA_OECONF = " \
|
|
--enable-shared \
|
|
--with-audio='${AUDIOMODS}' \
|
|
--with-module-suffix=.so \
|
|
${@bb.utils.contains('TUNE_FEATURES', 'neon', '--with-cpu=neon', '', d)} \
|
|
${@bb.utils.contains('TUNE_FEATURES', 'altivec', '--with-cpu=altivec', '', d)} \
|
|
"
|
|
|
|
# Fails to build with thumb-1 (qemuarm)
|
|
#| {standard input}: Assembler messages:
|
|
#| {standard input}:47: Error: selected processor does not support Thumb mode `smull r5,r6,r7,r4'
|
|
#| {standard input}:48: Error: shifts in CMP/MOV instructions are only supported in unified syntax -- `mov r5,r5,lsr#24'
|
|
#...
|
|
#| make[3]: *** [equalizer.lo] Error 1
|
|
ARM_INSTRUCTION_SET_armv4 = "arm"
|
|
ARM_INSTRUCTION_SET_armv5 = "arm"
|