mirror of
https://github.com/thead-yocto-mirror/meta-qt5
synced 2026-07-20 06:48:01 +02:00
3c4f2cba1f
Signed-off-by: Diego Rondini <diego.rondini@kynetics.com> Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
71 lines
2.3 KiB
BlitzBasic
71 lines
2.3 KiB
BlitzBasic
SUMMARY = "Python Qt5 Bindings"
|
|
AUTHOR = "Phil Thomson @ riverbank.co.uk"
|
|
HOMEPAGE = "http://riverbankcomputing.co.uk"
|
|
SECTION = "devel/python"
|
|
LICENSE = "GPLv3"
|
|
LIC_FILES_CHKSUM = "\
|
|
file://LICENSE;md5=d32239bcb673463ab874e80d47fae504 \
|
|
"
|
|
DEPENDS = "sip sip-native qtbase python"
|
|
|
|
SRC_URI = "\
|
|
${SOURCEFORGE_MIRROR}/pyqt/PyQt5_gpl-${PV}.tar.gz \
|
|
file://fix-sm.patch \
|
|
file://0001-qtabbar.sip-fix-build-with-accessibility-disabled.patch \
|
|
"
|
|
SRC_URI[md5sum] = "c3048e9d242f3e72fd393630da1d971a"
|
|
SRC_URI[sha256sum] = "ebd70515b30bbd6098fee29e6271a6696b1183c5530ee30e6ba9aaab195536e8"
|
|
|
|
S = "${WORKDIR}/PyQt5_gpl-${PV}"
|
|
|
|
|
|
inherit qmake5 pythonnative python-dir distro_features_check
|
|
# depends on qt4-x11-free
|
|
REQUIRED_DISTRO_FEATURES = "x11"
|
|
|
|
export BUILD_SYS
|
|
export HOST_SYS
|
|
export STAGING_INCDIR
|
|
export STAGING_LIBDIR
|
|
|
|
DISABLED_FEATURES = "PyQt_Desktop_OpenGL PyQt_Accessibility PyQt_SessionManager"
|
|
|
|
DISABLED_FEATURES_append_arm = " PyQt_qreal_double"
|
|
|
|
PYQT_MODULES = "QtCore QtGui QtNetwork QtWidgets"
|
|
PYQT_MODULES_aarch64 = "QtCore QtGui QtNetwork QtWidgets"
|
|
|
|
do_configure_prepend() {
|
|
cd ${S}
|
|
echo "py_platform = linux" > pyqt.cfg
|
|
echo "py_inc_dir = %(sysroot)/$includedir/python%(py_major).%(py_minor)" >> pyqt.cfg
|
|
echo "py_pylib_dir = %(sysroot)/${libdir}/python%(py_major).%(py_minor)" >> pyqt.cfg
|
|
echo "py_pylib_lib = python%(py_major).%(py_minor)mu" >> pyqt.cfg
|
|
echo "pyqt_module_dir = ${D}/${libdir}/python%(py_major).%(py_minor)/site-packages" >> pyqt.cfg
|
|
echo "pyqt_bin_dir = ${D}/${bindir}" >> pyqt.cfg
|
|
echo "pyqt_sip_dir = ${D}/${datadir}/sip/PyQt5" >> pyqt.cfg
|
|
echo "pyuic_interpreter = ${D}/${bindir}/python%(py_major).%(py_minor)" >> pyqt.cfg
|
|
echo "pyqt_disabled_features = ${DISABLED_FEATURES}" >> pyqt.cfg
|
|
echo "qt_shared = True" >> pyqt.cfg
|
|
QT_VERSION=`${OE_QMAKE_QMAKE} -query QT_VERSION`
|
|
echo "[Qt $QT_VERSION]" >> pyqt.cfg
|
|
echo "pyqt_modules = ${PYQT_MODULES}" >> pyqt.cfg
|
|
echo yes | python configure.py --verbose --qmake ${STAGING_BINDIR_NATIVE}/qt5/qmake --configuration pyqt.cfg --sysroot ${STAGING_DIR_HOST}
|
|
}
|
|
|
|
do_compile() {
|
|
cd ${S}
|
|
oe_runmake
|
|
}
|
|
|
|
do_install() {
|
|
cd ${S}
|
|
oe_runmake install
|
|
}
|
|
|
|
RDEPENDS_${PN} = "python-core python-sip"
|
|
|
|
FILES_${PN} += "${libdir}/${PYTHON_DIR}/site-packages ${datadir}/sip/PyQt5/"
|
|
FILES_${PN}-dbg += "${libdir}/${PYTHON_DIR}/site-packages/*/.debug/"
|
|
|