mirror of
https://github.com/thead-yocto-mirror/meta-qt5
synced 2026-09-18 13:11:55 +02:00
1a42aa78af
* LIC_FILES_CHKSUM were changed because of this small change:
commit 4343c4e731c3268614fc79c9c42b4e5e4d59d7e6
Author: Sze Howe Koh <szehowe.koh@gmail.com>
Date: Tue Jun 14 19:12:35 2016 +0800
Expand license scope from "Qt GUI Toolkit" to "Qt Toolkit"
* -no-nis option was removed from qtbase in:
commit 644d0e75240811212ed9fd0c21e3bd05db3ba5db
Author: Ralf Nolden <nolden@kde.org>
Date: Fri May 20 22:03:39 2016 +0200
Cleanup NIS support leftover from Qt 3/4
* allow to disable eglfs independently from gles2, because eglfs-egldevice
may be autodetected when libdrm was built before qtbase since this
upstream commit:
commit 5c6d27b8dfa695ab04766a1711b00421dba9c7d0
Author: Ralf Nolden <nolden@kde.org>
Date: Tue May 17 12:38:44 2016 +0200
Make eglfs-egldevice check work with pkgconfig as well
and then it fails to build, because libdrm could be removed from sysroot
and drm.h is missing.
* recipes-qt/qt5/qtquick1/0001-qdeclarativetextinput-update-to-match-QWidgetLineCon.patch
was resolved in upstream commit:
commit 26229cfa0b729313893af5674d604e8692dbb946
Author: Richard Moe Gustavsen <richard.gustavsen@theqtcompany.com>
Date: Tue Apr 26 15:08:34 2016 +0200
QDeclarativeTextInput: update API to use setBlinkingCursorEnabled
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
87 lines
5.1 KiB
BlitzBasic
87 lines
5.1 KiB
BlitzBasic
require qt5.inc
|
|
require qt5-git.inc
|
|
|
|
LICENSE = "BSD & LGPLv2+ | GPL-2.0"
|
|
LIC_FILES_CHKSUM = " \
|
|
file://LICENSE.GPLv2;md5=05832301944453ec79e40ba3c3cfceec \
|
|
file://Source/WebCore/rendering/RenderApplet.h;endline=22;md5=fb9694013ad71b78f8913af7a5959680 \
|
|
file://Source/WebKit/gtk/webkit/webkit.h;endline=21;md5=b4fbe9f4a944f1d071dba1d2c76b3351 \
|
|
file://Source/JavaScriptCore/parser/Parser.h;endline=21;md5=bd69f72183a7af673863f057576e21ee \
|
|
"
|
|
|
|
DEPENDS += "qtbase qtdeclarative icu ruby-native sqlite3 glib-2.0 libxslt"
|
|
|
|
# qemuarm build fails with:
|
|
# | {standard input}: Assembler messages:
|
|
# | {standard input}:106: Error: invalid immediate: 983040 is out of range
|
|
# | {standard input}:106: Error: value of 983040 too large for field of 2 bytes at 146
|
|
ARM_INSTRUCTION_SET_armv4 = "arm"
|
|
ARM_INSTRUCTION_SET_armv5 = "arm"
|
|
|
|
SRC_URI += "\
|
|
file://0001-qtwebkit-fix-QA-issue-bad-RPATH.patch \
|
|
file://0002-Remove-TEXTREL-tag-in-x86.patch \
|
|
file://0003-Exclude-backtrace-API-for-non-glibc-libraries.patch \
|
|
"
|
|
|
|
PACKAGECONFIG ??= "gstreamer qtlocation qtmultimedia qtsensors qtwebchannel \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'libxcomposite libxrender', '', d)} \
|
|
fontconfig \
|
|
"
|
|
PACKAGECONFIG[gstreamer] = "OE_GSTREAMER_ENABLED,,gstreamer1.0 gstreamer1.0-plugins-base"
|
|
PACKAGECONFIG[gstreamer010] = "OE_GSTREAMER010_ENABLED,,gstreamer gst-plugins-base"
|
|
PACKAGECONFIG[qtlocation] = "OE_QTLOCATION_ENABLED,,qtlocation"
|
|
PACKAGECONFIG[qtmultimedia] = "OE_QTMULTIMEDIA_ENABLED,,qtmultimedia"
|
|
PACKAGECONFIG[qtsensors] = "OE_QTSENSORS_ENABLED,,qtsensors"
|
|
PACKAGECONFIG[qtwebchannel] = "OE_QTWEBCHANNEL_ENABLED,,qtwebchannel"
|
|
PACKAGECONFIG[libwebp] = "OE_LIBWEBP_ENABLED,,libwebp"
|
|
PACKAGECONFIG[libxcomposite] = "OE_LIBXCOMPOSITE_ENABLED,,libxcomposite"
|
|
PACKAGECONFIG[libxrender] = "OE_LIBXRENDER_ENABLED,,libxrender"
|
|
PACKAGECONFIG[fontconfig] = "OE_FONTCONFIG_ENABLED,,fontconfig"
|
|
|
|
do_configure_prepend() {
|
|
export QMAKE_CACHE_EVAL="CONFIG+=${PACKAGECONFIG_CONFARGS}"
|
|
# disable gstreamer-1.0 test if it isn't enabled by PACKAGECONFIG
|
|
sed -e 's/\s\(packagesExist(".*\<gstreamer-1.0\>.*")\)/ OE_GSTREAMER_ENABLED:\1/' -i ${S}/Tools/qmake/mkspecs/features/features.prf
|
|
# disable gstreamer-0.10 test if it isn't enabled by PACKAGECONFIG
|
|
sed -e 's/\s\(packagesExist(".*\<gstreamer-0.10\>.*")\)/ OE_GSTREAMER010_ENABLED:\1/' -i ${S}/Tools/qmake/mkspecs/features/features.prf
|
|
# disable qtlocation test if it isn't enabled by PACKAGECONFIG
|
|
sed -e 's/\s\(qtHaveModule(positioning)\)/ OE_QTLOCATION_ENABLED:\1/' -i ${S}/Tools/qmake/mkspecs/features/features.prf
|
|
# disable qtmultimedia test if it isn't enabled by PACKAGECONFIG
|
|
sed -e 's/(video):\(qtHaveModule(multimediawidgets)\)/(video):OE_QTMULTIMEDIA_ENABLED:\1/' -i ${S}/Tools/qmake/mkspecs/features/features.prf
|
|
# disable qtsensors test if it isn't enabled by PACKAGECONFIG
|
|
sed -e 's/\s\(qtHaveModule(sensors)\)/ OE_QTSENSORS_ENABLED:\1/' -i ${S}/Tools/qmake/mkspecs/features/features.prf
|
|
# disable qtwebchannel test if it isn't enabled by PACKAGECONFIG
|
|
sed -e 's/\s\(qtHaveModule(webchannel)\)/ OE_QTWEBCHANNEL_ENABLED:\1/' -i ${S}/Source/WebKit2/Target.pri
|
|
sed -e 's/\s\(qtHaveModule(webchannel)\)/ OE_QTWEBCHANNEL_ENABLED:\1/' -i ${S}/Source/WebKit2/WebKit2.pri
|
|
# disable libwebp test if it isn't enabled by PACKAGECONFIG
|
|
sed -e 's/\s\(config_libwebp: \)/ OE_LIBWEBP_ENABLED:\1/' -i ${S}/Tools/qmake/mkspecs/features/features.prf
|
|
# disable libxcomposite test if it isn't enabled by PACKAGECONFIG
|
|
sed -e 's/\s\(config_libXcomposite: \)/ OE_LIBXCOMPOSITE_ENABLED:\1/' -i ${S}/Tools/qmake/mkspecs/features/features.prf
|
|
# disable libxrender test if it isn't enabled by PACKAGECONFIG
|
|
sed -e 's/\s\(config_libXrender: \)/ OE_LIBXRENDER_ENABLED:\1/' -i ${S}/Tools/qmake/mkspecs/features/features.prf
|
|
# disable fontconfig test if it isn't enabled by PACKAGECONFIG
|
|
sed -e 's/\s\(config_fontconfig: \)/ OE_FONTCONFIG_ENABLED:\1/' -i ${S}/Tools/qmake/mkspecs/features/features.prf
|
|
}
|
|
|
|
# qtwebkit gets terribly big when linking with all debug info, disable by default
|
|
QTWEBKIT_DEBUG = "QMAKE_CFLAGS+=-g0 QMAKE_CXXFLAGS+=-g0"
|
|
EXTRA_QMAKEVARS_PRE += "${QTWEBKIT_DEBUG}"
|
|
|
|
do_install_append() {
|
|
# Remove paths to workdir, qtwebkit is dead now, so I won't spend extra time trying to prevent this
|
|
# from some .prl or .prf file like for other modules
|
|
sed -i 's@-Wl,-no-whole-archive -L${B}[^ ]* @ @g' ${D}${libdir}/pkgconfig/Qt5WebKit.pc
|
|
}
|
|
|
|
# remove default ${PN}-examples* set in qt5.inc, because they conflicts with ${PN} from separate webkit-examples recipe
|
|
PACKAGES_remove = "${PN}-examples-dev ${PN}-examples-staticdev ${PN}-examples-dbg ${PN}-examples"
|
|
|
|
# make sure rb files are used from sysroot, not from host
|
|
# ruby-1.9.3-always-use-i386.patch is doing target_cpu=`echo $target_cpu | sed s/i.86/i386/`
|
|
# we need to replace it too (a bit longer version without importing re)
|
|
RUBY_SYS = "${@ '${BUILD_SYS}'.replace('i486', 'i386').replace('i586', 'i386').replace('i686', 'i386') }"
|
|
export RUBYLIB="${STAGING_DATADIR_NATIVE}/rubygems:${STAGING_LIBDIR_NATIVE}/ruby:${STAGING_LIBDIR_NATIVE}/ruby/${RUBY_SYS}"
|
|
|
|
SRCREV = "76e2732f013732461c09a1d6c6b4c77fcab1c0d0"
|