mirror of
https://github.com/thead-yocto-mirror/meta-qt5
synced 2026-09-18 13:11:55 +02:00
4020adfd51
* squashed with https://patchwork.openembedded.org/patch/135662/ qtwayland: update patch to apply with Qt 5.7.1 Update 0001-Fix-building-of-QWaylandIntegration-if-some-Qt5-feat.patch to apply on Qt 5.7.1 sources. Change-Id: I541f6fb5a706cdec3451dad015590a6624298a18 Signed-off-by: Mikko Gronoff <mikko.gronoff@qt.io> Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
127 lines
4.4 KiB
BlitzBasic
127 lines
4.4 KiB
BlitzBasic
DESCRIPTION = "Native version of Qt/[X11|Mac|Embedded]"
|
|
DEPENDS = "zlib-native dbus-native"
|
|
SECTION = "libs"
|
|
HOMEPAGE = "http://qt-project.org"
|
|
|
|
LICENSE = "GFDL-1.3 & BSD & ( GPL-3.0 & The-Qt-Company-GPL-Exception-1.0 | The-Qt-Company-Commercial ) & ( GPL-2.0+ | LGPL-3.0 | The-Qt-Company-Commercial )"
|
|
LIC_FILES_CHKSUM = " \
|
|
file://LICENSE.LGPL3;md5=e6a600fd5e1d9cbde2d983680233ad02 \
|
|
file://LICENSE.LGPLv21;md5=fb91571854638f10b2e5f36562661a5a \
|
|
file://LICENSE.LGPLv3;md5=a909b94c1c9674b2aa15ff03a86f518a \
|
|
file://LICENSE.GPL2;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
|
|
file://LICENSE.GPL3;md5=d32239bcb673463ab874e80d47fae504 \
|
|
file://LICENSE.GPL3-EXCEPT;md5=763d8c535a234d9a3fb682c7ecb6c073 \
|
|
file://LICENSE.GPLv3;md5=88e2b9117e6be406b5ed6ee4ca99a705 \
|
|
file://LGPL_EXCEPTION.txt;md5=9625233da42f9e0ce9d63651a9d97654 \
|
|
file://LICENSE.FDL;md5=6d9f2a9af4c8b8c3c769f6cc1b6aaf7e \
|
|
"
|
|
|
|
require qt5-native.inc
|
|
require qt5-git.inc
|
|
|
|
# common for qtbase-native, qtbase-nativesdk and qtbase
|
|
SRC_URI += "\
|
|
file://0001-Add-linux-oe-g-platform.patch \
|
|
file://0002-qlibraryinfo-allow-to-set-qt.conf-from-the-outside-u.patch \
|
|
file://0003-Add-external-hostbindir-option.patch \
|
|
file://0004-qt_module-Fix-pkgconfig-and-libtool-replacements.patch \
|
|
file://0005-configure-bump-path-length-from-256-to-512-character.patch \
|
|
file://0006-QOpenGLPaintDevice-sub-area-support.patch \
|
|
file://0007-linux-oe-g-Invert-conditional-for-defining-QT_SOCKLE.patch \
|
|
file://0008-configure-paths-for-target-qmake-properly.patch \
|
|
file://0009-Reorder-EGL-libraries-from-pkgconfig-and-defaults.patch \
|
|
file://0010-Pretend-Qt5-wasn-t-found-if-OE_QMAKE_PATH_EXTERNAL_H.patch \
|
|
"
|
|
|
|
# common for qtbase-native and nativesdk-qtbase
|
|
SRC_URI += " \
|
|
file://0011-Always-build-uic.patch \
|
|
file://0012-Add-external-hostbindir-option-for-native-sdk.patch \
|
|
"
|
|
|
|
CLEANBROKEN = "1"
|
|
|
|
QT_CONF_PATH = "${B}/qt.conf"
|
|
|
|
do_generate_qt_config_file() {
|
|
:
|
|
}
|
|
|
|
PACKAGECONFIG_CONFARGS = " \
|
|
-prefix ${prefix} \
|
|
-sysroot ${STAGING_DIR_NATIVE} \
|
|
-no-gcc-sysroot \
|
|
-system-zlib \
|
|
-no-libjpeg \
|
|
-no-libpng \
|
|
-no-gif \
|
|
-no-accessibility \
|
|
-no-cups \
|
|
-no-gui \
|
|
-no-qml-debug \
|
|
-no-sql-mysql \
|
|
-no-sql-sqlite \
|
|
-no-opengl \
|
|
-no-openssl \
|
|
-no-xcb \
|
|
-no-icu \
|
|
-verbose \
|
|
-release \
|
|
-prefix ${OE_QMAKE_PATH_PREFIX} \
|
|
-bindir ${OE_QMAKE_PATH_BINS} \
|
|
-libdir ${OE_QMAKE_PATH_LIBS} \
|
|
-headerdir ${OE_QMAKE_PATH_HEADERS} \
|
|
-archdatadir ${OE_QMAKE_PATH_ARCHDATA} \
|
|
-datadir ${OE_QMAKE_PATH_DATA} \
|
|
-docdir ${OE_QMAKE_PATH_DOCS} \
|
|
-sysconfdir ${OE_QMAKE_PATH_SETTINGS} \
|
|
-no-glib \
|
|
-no-iconv \
|
|
-silent \
|
|
-nomake examples \
|
|
-nomake tests \
|
|
-no-rpath \
|
|
-platform linux-oe-g++ \
|
|
"
|
|
|
|
# qtbase is exception, configure script is using our get(X)QEvalMakeConf and setBootstrapEvalVariable functions to read it from shell
|
|
export OE_QMAKE_COMPILER
|
|
export OE_QMAKE_CC
|
|
export OE_QMAKE_CFLAGS
|
|
export OE_QMAKE_CXX
|
|
export OE_QMAKE_CXXFLAGS
|
|
export OE_QMAKE_LINK
|
|
export OE_QMAKE_LDFLAGS
|
|
export OE_QMAKE_AR
|
|
export OE_QMAKE_STRIP
|
|
|
|
do_configure_prepend() {
|
|
MAKEFLAGS="${PARALLEL_MAKE}" ${S}/configure -opensource -confirm-license ${PACKAGECONFIG_CONFARGS} || die "Configuring qt failed. PACKAGECONFIG_CONFARGS was ${PACKAGECONFIG_CONFARGS}"
|
|
bin/qmake ${OE_QMAKE_DEBUG_OUTPUT} ${S} -o Makefile || die "Configuring qt with qmake failed. PACKAGECONFIG_CONFARGS was ${PACKAGECONFIG_CONFARGS}"
|
|
}
|
|
|
|
do_install() {
|
|
# Fix install paths for all
|
|
find . -name "Makefile*" | xargs sed -i "s,(INSTALL_ROOT)${STAGING_DIR_NATIVE}${STAGING_DIR_NATIVE},(INSTALL_ROOT)${STAGING_DIR_NATIVE},g"
|
|
|
|
oe_runmake install INSTALL_ROOT=${D}
|
|
|
|
if [ -d ${D}${STAGING_DIR_NATIVE}${STAGING_DIR_NATIVE} ] ; then
|
|
echo "Some files are installed in wrong directory ${D}${STAGING_DIR_NATIVE}"
|
|
cp -ra ${D}${STAGING_DIR_NATIVE}${STAGING_DIR_NATIVE}/* ${D}${STAGING_DIR_NATIVE}
|
|
rm -rf ${D}${STAGING_DIR_NATIVE}${STAGING_DIR_NATIVE}
|
|
# remove empty dirs
|
|
TMP=`dirname ${D}/${STAGING_DIR_NATIVE}${STAGING_DIR_NATIVE}`
|
|
while test ${TMP} != ${D}${STAGING_DIR_NATIVE}; do
|
|
rmdir ${TMP}
|
|
TMP=`dirname ${TMP}`;
|
|
done
|
|
fi
|
|
|
|
# for modules which are still using syncqt and call qtPrepareTool(QMAKE_SYNCQT, syncqt)
|
|
# e.g. qt3d, qtwayland
|
|
ln -sf syncqt.pl ${D}${OE_QMAKE_PATH_QT_BINS}/syncqt
|
|
}
|
|
|
|
SRCREV = "a55f36211efe1bb0d6717c8545366120bd6dfd9f"
|