mirror of
https://github.com/thead-yocto-mirror/meta-qt5
synced 2026-06-21 17:02:34 +02:00
b2a958a4cd
* fixes: sip: QOpenGLFramebufferObject is undefined in default nodistro setup without opengl in DISTRO_FEATURES Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
64 lines
2.3 KiB
PHP
64 lines
2.3 KiB
PHP
SUMMARY = "Python Qt5 Bindings"
|
|
AUTHOR = "Phil Thomson @ riverbank.co.uk"
|
|
HOMEPAGE = "http://riverbankcomputing.co.uk"
|
|
SECTION = "devel/python"
|
|
LICENSE = "GPLv3"
|
|
LIC_FILES_CHKSUM = "\
|
|
file://LICENSE;md5=d32239bcb673463ab874e80d47fae504 \
|
|
"
|
|
SRC_URI = "\
|
|
https://www.riverbankcomputing.com/static/Downloads/PyQt5/${PV}/PyQt5-${PV}.tar.gz \
|
|
"
|
|
SRC_URI[md5sum] = "c1023cb9c3d29a89fc109b163a0175c0"
|
|
SRC_URI[sha256sum] = "adc17c077bf233987b8e43ada87d1e0deca9bd71a13e5fd5fc377482ed69c827"
|
|
|
|
S = "${WORKDIR}/PyQt5-${PV}"
|
|
|
|
inherit qmake5
|
|
DEPENDS = "qtbase qtdeclarative qtquickcontrols2"
|
|
|
|
export BUILD_SYS
|
|
export HOST_SYS
|
|
export STAGING_INCDIR
|
|
export STAGING_LIBDIR
|
|
|
|
PARALLEL_MAKEINST = ""
|
|
|
|
DISABLED_FEATURES = "PyQt_Desktop_OpenGL PyQt_Accessibility PyQt_SessionManager ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', '', 'PyQt_OpenGL', d)}"
|
|
|
|
DISABLED_FEATURES_append_arm = " PyQt_qreal_double"
|
|
|
|
PYQT_MODULES = "QtCore QtGui QtNetwork QtXml QtNetwork QtQml ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'QtQuick QtWidgets QtQuickWidgets', '', d)}"
|
|
|
|
do_configure_prepend() {
|
|
cd ${S}
|
|
echo "py_platform = linux" > pyqt.cfg
|
|
echo "py_inc_dir = %(sysroot)/$includedir/python%(py_major).%(py_minor)${PYTHON_ABI}" >> pyqt.cfg
|
|
echo "py_pylib_dir = %(sysroot)/${libdir}/python%(py_major).%(py_minor)" >> pyqt.cfg
|
|
echo "py_pylib_lib = python$%(py_major).%(py_minor)" >> pyqt.cfg
|
|
echo "pyqt_module_dir = ${D}/${libdir}/python%(py_major).%(py_minor)/site-packages" >> pyqt.cfg
|
|
echo "pyqt_bin_dir = ${D}/${bindir}" >> pyqt.cfg
|
|
echo "pyqt_sip_dir = ${D}/${datadir}/sip/PyQt5" >> pyqt.cfg
|
|
echo "pyuic_interpreter = ${D}/${bindir}/python%(py_major).%(py_minor)" >> pyqt.cfg
|
|
echo "pyqt_disabled_features = ${DISABLED_FEATURES}" >> pyqt.cfg
|
|
echo "qt_shared = True" >> pyqt.cfg
|
|
QT_VERSION=`${OE_QMAKE_QMAKE} -query QT_VERSION`
|
|
echo "[Qt $QT_VERSION]" >> pyqt.cfg
|
|
echo "pyqt_modules = ${PYQT_MODULES}" >> pyqt.cfg
|
|
echo yes | ${PYTHON} configure.py --verbose --qmake ${STAGING_BINDIR_NATIVE}/${QT_DIR_NAME}/qmake --configuration pyqt.cfg --sysroot ${STAGING_DIR_HOST}
|
|
}
|
|
|
|
do_compile() {
|
|
cd ${S}
|
|
oe_runmake
|
|
}
|
|
|
|
do_install() {
|
|
cd ${S}
|
|
oe_runmake MAKEFLAGS='-j 1' install
|
|
}
|
|
|
|
FILES_${PN} += "${libdir}/${PYTHON_DIR}/site-packages ${datadir}/sip/PyQt5/"
|
|
|
|
RDEPENDS_${PN} = "qtbase qtdeclarative qtquickcontrols2 qtquickcontrols2-mkspecs"
|