mirror of
https://github.com/thead-yocto-mirror/meta-riscv
synced 2026-09-16 12:14:20 +02:00
30eb9be70c
Update to the latest version of the RISC-V Proxy Kernel. This means we are running an updated bbl. Signed-off-by: Alistair Francis <alistair.francis@wdc.com>
53 lines
1.4 KiB
BlitzBasic
53 lines
1.4 KiB
BlitzBasic
SUMMARY = "RISC-V Proxy Kernel"
|
|
DESCRIPTION = "RISC-V Proxy Kernel"
|
|
LICENSE = "GPLv2+"
|
|
|
|
LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.GPLv2;md5=751419260aa954499f7abaabaa882bbe"
|
|
|
|
SRCREV = "7bee30c1ff56975041ffc67cd0170d7477aba865"
|
|
SRC_URI = "git://github.com/riscv/riscv-pk.git \
|
|
file://0001-add-acinclude.m4.patch \
|
|
file://0002-Makefile.in-Don-t-specify-a-march-if-one-isn-t-speci.patch \
|
|
"
|
|
|
|
PACKAGE_ARCH = "${MACHINE_ARCH}"
|
|
|
|
LDFLAGS_append = " -Wl,--build-id=none"
|
|
|
|
inherit autotools
|
|
|
|
EXTRA_OECONF += "--enable-logo --with-payload=${DEPLOY_DIR_IMAGE}/${RISCV_BBL_PAYLOAD}"
|
|
|
|
INHIBIT_PACKAGE_STRIP = "1"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
# bbl_payload needs kernel deployed artifacts (e.g. vmlinux)
|
|
do_compile[depends] += "virtual/kernel:do_deploy"
|
|
|
|
do_install_prepend () {
|
|
install -d ${D}${datadir}/riscv-pk
|
|
install -m 755 ${WORKDIR}/build/bbl ${D}${datadir}/riscv-pk
|
|
}
|
|
|
|
do_install_append() {
|
|
rm -rf ${D}${exec_prefix}/riscv64-*
|
|
}
|
|
|
|
do_install_append_freedom-u540() {
|
|
${OBJCOPY} -S -O binary --change-addresses -0x80000000 \
|
|
${WORKDIR}/build/bbl ${WORKDIR}/build/bbl.bin
|
|
}
|
|
|
|
do_deploy () {
|
|
install -d ${DEPLOY_DIR_IMAGE}
|
|
install -m 755 ${WORKDIR}/build/bbl ${DEPLOY_DIR_IMAGE}/bbl
|
|
}
|
|
|
|
do_deploy_append_freedom-u540() {
|
|
install -m 755 ${WORKDIR}/build/bbl.bin ${DEPLOY_DIR_IMAGE}/bbl.bin
|
|
}
|
|
addtask deploy before do_build after do_install
|
|
|
|
COMPATIBLE_HOST = "(riscv64|riscv32).*-linux"
|