mirror of
https://github.com/thead-yocto-mirror/meta-openembedded
synced 2026-09-17 20:51:57 +02:00
dfc3ed7083
41.2 ==== * Fix blank screen when unplugging docking station [Jonas; !2097] * Prefer GBM over EGLStream where possible [Jonas; !2051, !2052] * Fix unredirected Xwayland windows not getting updated [Michel; !2112] * Improve anti-aliasing of background corners [Daniel; !2102] * Copy damage rectangles to secondary GPU [Piotr; !2033] * Improve Wacom tablet mapping [Carlos; !2107] * Fixed crashes [Jonas, Daniel; #1950, !2081, !2104, !1991, !2127] * Misc. bug fixes and cleanups [Simon, Corentin, Pascal; !2049, !2119, !2138] 41.1 ==== * Fix monitor screencast scanouts [Michel; !1914] * dma-buf: Use alpha-less pixel formats where appropriate [Robert; !1810] * wayland: Allow clients to maximize windows regardless of constraints [Christian; !1997] * Handle hotplug events without relevant changes more effectively [Marco; !1964] * Improve error reporting when startup fails [Jonas; !1994] * dma-buf: Add support for ABGR and XBGR formats [Erfan; !1999] * Fix X11 middle button emulation setting [José; !2000] * Include server-side shadows in window screenshots [Robert; !1996] * Don't change workspaces of unmanaged windows [Sebastian; !2003] * Reset idletime when unplugging the power cable [Bastien; !2029] * xwayland: Avoid unnecessary _NET_WM_STATE events [Dor; !2032] * Fix videos in Firefox stuttering in overview [Robert; !2034] * Don't use atomic mode setting for virtio_gpu driver [Jonas; !2040] * Improve on-screen keyboard on X11 [Sebastian, Ray; !1955, !2039] * misc [Daniel, Jonas, Corentin, Robert; !1992, !2007, !2008, !2026, !2044] * Fix text glitches after size changes [Sebastian; !2006] * Fix reporting output rotation to xwayland [Olivier; !2050] * wayland: Accept final preference of drop destination [Robert; !2043] * Fix erratic scrolling in GTK apps [Carlos; gnome-shell#4647] * Fix tilt direction of pen/tablet inputs [Quytelda; !2065] * Use b/w unicode for tablet mode OSD [Carlos; !2064] * Fix negative paint volume offscreen effect [Sebastian; !2031] * Only add paint volumes of mapped actors to stage clip [Robert; !2035] * Fix mapping tablet input to correct monitor [Jason; !1934] * Misc. bug fixes and cleanups Signed-off-by: Andreas Müller <schnitzeltony@gmail.com> Signed-off-by: Khem Raj <raj.khem@gmail.com>
99 lines
3.0 KiB
BlitzBasic
99 lines
3.0 KiB
BlitzBasic
SUMMARY = "Window and compositing manager based on Clutter"
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
|
|
DEPENDS = " \
|
|
xserver-xorg-cvt-native \
|
|
wayland-native \
|
|
virtual/libx11 \
|
|
graphene \
|
|
gtk+3 \
|
|
gdk-pixbuf \
|
|
cairo \
|
|
pango \
|
|
gsettings-desktop-schemas \
|
|
json-glib \
|
|
gnome-desktop3 \
|
|
gnome-settings-daemon \
|
|
libxtst \
|
|
libxkbfile \
|
|
xinerama \
|
|
xwayland \
|
|
"
|
|
|
|
GNOMEBASEBUILDCLASS = "meson"
|
|
|
|
inherit gnomebase gsettings gobject-introspection gettext features_check
|
|
|
|
SRC_URI[archive.sha256sum] = "00dfa812f1c486d74a2b73f42045ae1182f9246c7794d67d74b5e543ea700617"
|
|
|
|
# x11 is still manadatory - see meson.build
|
|
REQUIRED_DISTRO_FEATURES = "wayland x11 polkit"
|
|
|
|
# systemd can be replaced by libelogind (not available atow - make systemd
|
|
# mandatory distro feature)
|
|
LOGIND ?= "systemd"
|
|
REQUIRED_DISTRO_FEATURES += "systemd"
|
|
|
|
# profiler requires sysprof 3.34 which is not willing to build atow
|
|
PACKAGECONFIG ??= " \
|
|
native-backend \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'opengl x11', 'opengl glx', '', d)} \
|
|
sm \
|
|
startup-notification \
|
|
"
|
|
|
|
EXTRA_OEMESON += " \
|
|
-Dtests=false \
|
|
-Dnative_tests=false \
|
|
-Dxwayland_path=${bindir}/Xwayland \
|
|
"
|
|
|
|
# combi-config - see meson_options.txt for more details
|
|
PACKAGECONFIG[native-backend] = "-Dnative_backend=true -Dudev=true, -Dnative_backend=false -Dudev=false, libdrm virtual/libgbm libinput ${LOGIND} virtual/egl virtual/libgles2 udev"
|
|
PACKAGECONFIG[opengl] = "-Dopengl=true, -Dopengl=true, virtual/libgl"
|
|
PACKAGECONFIG[glx] = "-Dglx=true, -Dglx=false"
|
|
PACKAGECONFIG[libwacom] = "-Dlibwacom=true, -Dlibwacom=false, libwacom"
|
|
# Remove depending on pipewire-0.2 when mutter is upgraded to 3.36+
|
|
PACKAGECONFIG[remote-desktop] = "-Dremote_desktop=true, -Dremote_desktop=false, pipewire"
|
|
PACKAGECONFIG[sm] = "-Dsm=true, -Dsm=false, libsm"
|
|
PACKAGECONFIG[profiler] = "-Dprofiler=true,-Dprofiler=false,sysprof"
|
|
PACKAGECONFIG[startup-notification] = "-Dstartup_notification=true, -Dstartup_notification=false, startup-notification, startup-notification"
|
|
|
|
MUTTER_API_NAME = "mutter-9"
|
|
|
|
do_install:append() {
|
|
# Add gir links in standard paths. That makes dependents life much easier
|
|
# to find them
|
|
install -d ${D}${datadir}/gir-1.0
|
|
for gir_full in `find ${D}${libdir}/${MUTTER_API_NAME} -name '*.gir'`; do
|
|
gir=`basename "$gir_full"`
|
|
ln -sr "${D}${libdir}/${MUTTER_API_NAME}/$gir" "${D}${datadir}/gir-1.0/$gir"
|
|
done
|
|
}
|
|
|
|
GSETTINGS_PACKAGE = "${PN}-gsettings"
|
|
|
|
PACKAGES =+ "${PN}-tests ${PN}-gsettings"
|
|
|
|
FILES:${PN} += " \
|
|
${datadir}/gnome-control-center \
|
|
${libdir}/${MUTTER_API_NAME}/lib*${SOLIBS} \
|
|
${libdir}/${MUTTER_API_NAME}/*.typelib \
|
|
${libdir}/${MUTTER_API_NAME}/plugins \
|
|
"
|
|
|
|
FILES:${PN}-tests += " \
|
|
${datadir}/installed-tests \
|
|
${datadir}/${MUTTER_API_NAME}/tests \
|
|
${libexecdir}/installed-tests/${MUTTER_API_NAME} \
|
|
"
|
|
|
|
FILES:${PN}-dev += " \
|
|
${libdir}/${MUTTER_API_NAME}/*.gir \
|
|
${libdir}/${MUTTER_API_NAME}/lib*.so \
|
|
"
|
|
|
|
RDEPENDS:${PN} += "zenity ${PN}-gsettings"
|
|
|